cgqrts.f

Go to the documentation of this file.

*> \brief \b CGQRTS
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE CGQRTS( N, M, P, A, AF, Q, R, LDA, TAUA, B, BF, Z, T,
*                          BWK, LDB, TAUB, WORK, LWORK, RWORK, RESULT )
*
*       .. Scalar Arguments ..
*       INTEGER            LDA, LDB, LWORK, M, P, N
*       ..
*       .. Array Arguments ..
*       REAL               RWORK( * ), RESULT( 4 )
*       COMPLEX            A( LDA, * ), AF( LDA, * ), R( LDA, * ),
*      $                   Q( LDA, * ), B( LDB, * ), BF( LDB, * ),
*      $                   T( LDB, * ), Z( LDB, * ), BWK( LDB, * ),
*      $                   TAUA( * ), TAUB( * ), WORK( LWORK )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CGQRTS tests CGGQRF, which computes the GQR factorization of an
*> N-by-M matrix A and a N-by-P matrix B: A = Q*R and B = Q*T*Z.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of rows of the matrices A and B.  N >= 0.
*> \endverbatim
*>
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of columns of the matrix A.  M >= 0.
*> \endverbatim
*>
*> \param[in] P
*> \verbatim
*>          P is INTEGER
*>          The number of columns of the matrix B.  P >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is COMPLEX array, dimension (LDA,M)
*>          The N-by-M matrix A.
*> \endverbatim
*>
*> \param[out] AF
*> \verbatim
*>          AF is COMPLEX array, dimension (LDA,N)
*>          Details of the GQR factorization of A and B, as returned
*>          by CGGQRF, see CGGQRF for further details.
*> \endverbatim
*>
*> \param[out] Q
*> \verbatim
*>          Q is COMPLEX array, dimension (LDA,N)
*>          The M-by-M unitary matrix Q.
*> \endverbatim
*>
*> \param[out] R
*> \verbatim
*>          R is COMPLEX array, dimension (LDA,MAX(M,N))
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the arrays A, AF, R and Q.
*>          LDA >= max(M,N).
*> \endverbatim
*>
*> \param[out] TAUA
*> \verbatim
*>          TAUA is COMPLEX array, dimension (min(M,N))
*>          The scalar factors of the elementary reflectors, as returned
*>          by CGGQRF.
*> \endverbatim
*>
*> \param[in] B
*> \verbatim
*>          B is COMPLEX array, dimension (LDB,P)
*>          On entry, the N-by-P matrix A.
*> \endverbatim
*>
*> \param[out] BF
*> \verbatim
*>          BF is COMPLEX array, dimension (LDB,N)
*>          Details of the GQR factorization of A and B, as returned
*>          by CGGQRF, see CGGQRF for further details.
*> \endverbatim
*>
*> \param[out] Z
*> \verbatim
*>          Z is COMPLEX array, dimension (LDB,P)
*>          The P-by-P unitary matrix Z.
*> \endverbatim
*>
*> \param[out] T
*> \verbatim
*>          T is COMPLEX array, dimension (LDB,max(P,N))
*> \endverbatim
*>
*> \param[out] BWK
*> \verbatim
*>          BWK is COMPLEX array, dimension (LDB,N)
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the arrays B, BF, Z and T.
*>          LDB >= max(P,N).
*> \endverbatim
*>
*> \param[out] TAUB
*> \verbatim
*>          TAUB is COMPLEX array, dimension (min(P,N))
*>          The scalar factors of the elementary reflectors, as returned
*>          by SGGRQF.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The dimension of the array WORK, LWORK >= max(N,M,P)**2.
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is REAL array, dimension (max(N,M,P))
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is REAL array, dimension (4)
*>          The test ratios:
*>            RESULT(1) = norm( R - Q'*A ) / ( MAX(M,N)*norm(A)*ULP)
*>            RESULT(2) = norm( T*Z - Q'*B ) / (MAX(P,N)*norm(B)*ULP)
*>            RESULT(3) = norm( I - Q'*Q ) / ( M*ULP )
*>            RESULT(4) = norm( I - Z'*Z ) / ( P*ULP )
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup complex_eig
*
*  =====================================================================
      SUBROUTINE cgqrts( N, M, P, A, AF, Q, R, LDA, TAUA, B, BF, Z, T,
     $                   BWK, LDB, TAUB, WORK, LWORK, RWORK, RESULT )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LDB, LWORK, M, P, N
*     ..
*     .. Array Arguments ..
      REAL               RWORK( * ), RESULT( 4 )
      COMPLEX            A( LDA, * ), AF( LDA, * ), R( LDA, * ),
     $                   q( lda, * ), b( ldb, * ), bf( ldb, * ),
     $                   t( ldb, * ), z( ldb, * ), bwk( ldb, * ),
     $                   taua( * ), taub( * ), work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            CZERO, CONE
      parameter( czero = ( 0.0e+0, 0.0e+0 ),
     $                   cone = ( 1.0e+0, 0.0e+0 ) )
      COMPLEX            CROGUE
      parameter( crogue = ( -1.0e+10, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO
      REAL               ANORM, BNORM, ULP, UNFL, RESID
*     ..
*     .. External Functions ..
      REAL               SLAMCH, CLANGE, CLANHE
      EXTERNAL           slamch, clange, clanhe
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm, clacpy, claset, cungqr,
     $                   cungrq, cherk
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, real
*     ..
*     .. Executable Statements ..
*
      ulp = slamch( 'Precision' )
      unfl = slamch( 'Safe minimum' )
*
*     Copy the matrix A to the array AF.
*
      CALL clacpy( 'Full', n, m, a, lda, af, lda )
      CALL clacpy( 'Full', n, p, b, ldb, bf, ldb )
*
      anorm = max( clange( '1', n, m, a, lda, rwork ), unfl )
      bnorm = max( clange( '1', n, p, b, ldb, rwork ), unfl )
*
*     Factorize the matrices A and B in the arrays AF and BF.
*
      CALL cggqrf( n, m, p, af, lda, taua, bf, ldb, taub, work,
     $             lwork, info )
*
*     Generate the N-by-N matrix Q
*
      CALL claset( 'Full', n, n, crogue, crogue, q, lda )
      CALL clacpy( 'Lower', n-1, m, af( 2,1 ), lda, q( 2,1 ), lda )
      CALL cungqr( n, n, min( n, m ), q, lda, taua, work, lwork, info )
*
*     Generate the P-by-P matrix Z
*
      CALL claset( 'Full', p, p, crogue, crogue, z, ldb )
      IF( n.LE.p ) THEN
         IF( n.GT.0 .AND. n.LT.p )
     $      CALL clacpy( 'Full', n, p-n, bf, ldb, z( p-n+1, 1 ), ldb )
         IF( n.GT.1 )
     $      CALL clacpy( 'Lower', n-1, n-1, bf( 2, p-n+1 ), ldb,
     $                    z( p-n+2, p-n+1 ), ldb )
      ELSE
         IF( p.GT.1)
     $      CALL clacpy( 'Lower', p-1, p-1, bf( n-p+2, 1 ), ldb,
     $                    z( 2, 1 ), ldb )
      END IF
      CALL cungrq( p, p, min( n, p ), z, ldb, taub, work, lwork, info )
*
*     Copy R
*
      CALL claset( 'Full', n, m, czero, czero, r, lda )
      CALL clacpy( 'Upper', n, m, af, lda, r, lda )
*
*     Copy T
*
      CALL claset( 'Full', n, p, czero, czero, t, ldb )
      IF( n.LE.p ) THEN
         CALL clacpy( 'Upper', n, n, bf( 1, p-n+1 ), ldb, t( 1, p-n+1 ),
     $                ldb )
      ELSE
         CALL clacpy( 'Full', n-p, p, bf, ldb, t, ldb )
         CALL clacpy( 'Upper', p, p, bf( n-p+1, 1 ), ldb, t( n-p+1, 1 ),
     $                ldb )
      END IF
*
*     Compute R - Q'*A
*
      CALL cgemm( 'Conjugate transpose', 'No transpose', n, m, n, -cone,
     $            q, lda, a, lda, cone, r, lda )
*
*     Compute norm( R - Q'*A ) / ( MAX(M,N)*norm(A)*ULP ) .
*
      resid = clange( '1', n, m, r, lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / real( max(1,m,n) ) ) / anorm ) / ulp
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute T*Z - Q'*B
*
      CALL cgemm( 'No Transpose', 'No transpose', n, p, p, cone, t, ldb,
     $            z, ldb, czero, bwk, ldb )
      CALL cgemm( 'Conjugate transpose', 'No transpose', n, p, n, -cone,
     $            q, lda, b, ldb, cone, bwk, ldb )
*
*     Compute norm( T*Z - Q'*B ) / ( MAX(P,N)*norm(A)*ULP ) .
*
      resid = clange( '1', n, p, bwk, ldb, rwork )
      IF( bnorm.GT.zero ) THEN
         result( 2 ) = ( ( resid / real( max(1,p,n ) ) )/bnorm ) / ulp
      ELSE
         result( 2 ) = zero
      END IF
*
*     Compute I - Q'*Q
*
      CALL claset( 'Full', n, n, czero, cone, r, lda )
      CALL cherk( 'Upper', 'Conjugate transpose', n, n, -one, q, lda,
     $            one, r, lda )
*
*     Compute norm( I - Q'*Q ) / ( N * ULP ) .
*
      resid = clanhe( '1', 'Upper', n, r, lda, rwork )
      result( 3 ) = ( resid / real( max( 1, n ) ) ) / ulp
*
*     Compute I - Z'*Z
*
      CALL claset( 'Full', p, p, czero, cone, t, ldb )
      CALL cherk( 'Upper', 'Conjugate transpose', p, p, -one, z, ldb,
     $            one, t, ldb )
*
*     Compute norm( I - Z'*Z ) / ( P*ULP ) .
*
      resid = clanhe( '1', 'Upper', p, t, ldb, rwork )
      result( 4 ) = ( resid / real( max( 1, p ) ) ) / ulp
*
      RETURN
*
*     End of CGQRTS
*
      END