LAPACK  3.10.1
LAPACK: Linear Algebra PACKage

◆ zunbdb1()

subroutine zunbdb1 ( integer  M,
integer  P,
integer  Q,
complex*16, dimension(ldx11,*)  X11,
integer  LDX11,
complex*16, dimension(ldx21,*)  X21,
integer  LDX21,
double precision, dimension(*)  THETA,
double precision, dimension(*)  PHI,
complex*16, dimension(*)  TAUP1,
complex*16, dimension(*)  TAUP2,
complex*16, dimension(*)  TAUQ1,
complex*16, dimension(*)  WORK,
integer  LWORK,
integer  INFO 
)

ZUNBDB1

Download ZUNBDB1 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZUNBDB1 simultaneously bidiagonalizes the blocks of a tall and skinny
 matrix X with orthonomal columns:

                            [ B11 ]
      [ X11 ]   [ P1 |    ] [  0  ]
      [-----] = [---------] [-----] Q1**T .
      [ X21 ]   [    | P2 ] [ B21 ]
                            [  0  ]

 X11 is P-by-Q, and X21 is (M-P)-by-Q. Q must be no larger than P,
 M-P, or M-Q. Routines ZUNBDB2, ZUNBDB3, and ZUNBDB4 handle cases in
 which Q is not the minimum dimension.

 The unitary matrices P1, P2, and Q1 are P-by-P, (M-P)-by-(M-P),
 and (M-Q)-by-(M-Q), respectively. They are represented implicitly by
 Householder vectors.

 B11 and B12 are Q-by-Q bidiagonal matrices represented implicitly by
 angles THETA, PHI.
Parameters
[in]M
          M is INTEGER
           The number of rows X11 plus the number of rows in X21.
[in]P
          P is INTEGER
           The number of rows in X11. 0 <= P <= M.
[in]Q
          Q is INTEGER
           The number of columns in X11 and X21. 0 <= Q <=
           MIN(P,M-P,M-Q).
[in,out]X11
          X11 is COMPLEX*16 array, dimension (LDX11,Q)
           On entry, the top block of the matrix X to be reduced. On
           exit, the columns of tril(X11) specify reflectors for P1 and
           the rows of triu(X11,1) specify reflectors for Q1.
[in]LDX11
          LDX11 is INTEGER
           The leading dimension of X11. LDX11 >= P.
[in,out]X21
          X21 is COMPLEX*16 array, dimension (LDX21,Q)
           On entry, the bottom block of the matrix X to be reduced. On
           exit, the columns of tril(X21) specify reflectors for P2.
[in]LDX21
          LDX21 is INTEGER
           The leading dimension of X21. LDX21 >= M-P.
[out]THETA
          THETA is DOUBLE PRECISION array, dimension (Q)
           The entries of the bidiagonal blocks B11, B21 are defined by
           THETA and PHI. See Further Details.
[out]PHI
          PHI is DOUBLE PRECISION array, dimension (Q-1)
           The entries of the bidiagonal blocks B11, B21 are defined by
           THETA and PHI. See Further Details.
[out]TAUP1
          TAUP1 is COMPLEX*16 array, dimension (P)
           The scalar factors of the elementary reflectors that define
           P1.
[out]TAUP2
          TAUP2 is COMPLEX*16 array, dimension (M-P)
           The scalar factors of the elementary reflectors that define
           P2.
[out]TAUQ1
          TAUQ1 is COMPLEX*16 array, dimension (Q)
           The scalar factors of the elementary reflectors that define
           Q1.
[out]WORK
          WORK is COMPLEX*16 array, dimension (LWORK)
[in]LWORK
          LWORK is INTEGER
           The dimension of the array WORK. LWORK >= M-Q.

           If LWORK = -1, then a workspace query is assumed; the routine
           only calculates the optimal size of the WORK array, returns
           this value as the first entry of the WORK array, and no error
           message related to LWORK is issued by XERBLA.
[out]INFO
          INFO is INTEGER
           = 0:  successful exit.
           < 0:  if INFO = -i, the i-th argument had an illegal value.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
  The upper-bidiagonal blocks B11, B21 are represented implicitly by
  angles THETA(1), ..., THETA(Q) and PHI(1), ..., PHI(Q-1). Every entry
  in each bidiagonal band is a product of a sine or cosine of a THETA
  with a sine or cosine of a PHI. See [1] or ZUNCSD for details.

  P1, P2, and Q1 are represented as products of elementary reflectors.
  See ZUNCSD2BY1 for details on generating P1, P2, and Q1 using ZUNGQR
  and ZUNGLQ.
References:
[1] Brian D. Sutton. Computing the complete CS decomposition. Numer. Algorithms, 50(1):33-65, 2009.

Definition at line 201 of file zunbdb1.f.

203 *
204 * -- LAPACK computational routine --
205 * -- LAPACK is a software package provided by Univ. of Tennessee, --
206 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
207 *
208 * .. Scalar Arguments ..
209  INTEGER INFO, LWORK, M, P, Q, LDX11, LDX21
210 * ..
211 * .. Array Arguments ..
212  DOUBLE PRECISION PHI(*), THETA(*)
213  COMPLEX*16 TAUP1(*), TAUP2(*), TAUQ1(*), WORK(*),
214  $ X11(LDX11,*), X21(LDX21,*)
215 * ..
216 *
217 * ====================================================================
218 *
219 * .. Parameters ..
220  COMPLEX*16 ONE
221  parameter( one = (1.0d0,0.0d0) )
222 * ..
223 * .. Local Scalars ..
224  DOUBLE PRECISION C, S
225  INTEGER CHILDINFO, I, ILARF, IORBDB5, LLARF, LORBDB5,
226  $ LWORKMIN, LWORKOPT
227  LOGICAL LQUERY
228 * ..
229 * .. External Subroutines ..
230  EXTERNAL zlarf, zlarfgp, zunbdb5, zdrot, xerbla
231  EXTERNAL zlacgv
232 * ..
233 * .. External Functions ..
234  DOUBLE PRECISION DZNRM2
235  EXTERNAL dznrm2
236 * ..
237 * .. Intrinsic Function ..
238  INTRINSIC atan2, cos, max, sin, sqrt
239 * ..
240 * .. Executable Statements ..
241 *
242 * Test input arguments
243 *
244  info = 0
245  lquery = lwork .EQ. -1
246 *
247  IF( m .LT. 0 ) THEN
248  info = -1
249  ELSE IF( p .LT. q .OR. m-p .LT. q ) THEN
250  info = -2
251  ELSE IF( q .LT. 0 .OR. m-q .LT. q ) THEN
252  info = -3
253  ELSE IF( ldx11 .LT. max( 1, p ) ) THEN
254  info = -5
255  ELSE IF( ldx21 .LT. max( 1, m-p ) ) THEN
256  info = -7
257  END IF
258 *
259 * Compute workspace
260 *
261  IF( info .EQ. 0 ) THEN
262  ilarf = 2
263  llarf = max( p-1, m-p-1, q-1 )
264  iorbdb5 = 2
265  lorbdb5 = q-2
266  lworkopt = max( ilarf+llarf-1, iorbdb5+lorbdb5-1 )
267  lworkmin = lworkopt
268  work(1) = lworkopt
269  IF( lwork .LT. lworkmin .AND. .NOT.lquery ) THEN
270  info = -14
271  END IF
272  END IF
273  IF( info .NE. 0 ) THEN
274  CALL xerbla( 'ZUNBDB1', -info )
275  RETURN
276  ELSE IF( lquery ) THEN
277  RETURN
278  END IF
279 *
280 * Reduce columns 1, ..., Q of X11 and X21
281 *
282  DO i = 1, q
283 *
284  CALL zlarfgp( p-i+1, x11(i,i), x11(i+1,i), 1, taup1(i) )
285  CALL zlarfgp( m-p-i+1, x21(i,i), x21(i+1,i), 1, taup2(i) )
286  theta(i) = atan2( dble( x21(i,i) ), dble( x11(i,i) ) )
287  c = cos( theta(i) )
288  s = sin( theta(i) )
289  x11(i,i) = one
290  x21(i,i) = one
291  CALL zlarf( 'L', p-i+1, q-i, x11(i,i), 1, dconjg(taup1(i)),
292  $ x11(i,i+1), ldx11, work(ilarf) )
293  CALL zlarf( 'L', m-p-i+1, q-i, x21(i,i), 1, dconjg(taup2(i)),
294  $ x21(i,i+1), ldx21, work(ilarf) )
295 *
296  IF( i .LT. q ) THEN
297  CALL zdrot( q-i, x11(i,i+1), ldx11, x21(i,i+1), ldx21, c,
298  $ s )
299  CALL zlacgv( q-i, x21(i,i+1), ldx21 )
300  CALL zlarfgp( q-i, x21(i,i+1), x21(i,i+2), ldx21, tauq1(i) )
301  s = dble( x21(i,i+1) )
302  x21(i,i+1) = one
303  CALL zlarf( 'R', p-i, q-i, x21(i,i+1), ldx21, tauq1(i),
304  $ x11(i+1,i+1), ldx11, work(ilarf) )
305  CALL zlarf( 'R', m-p-i, q-i, x21(i,i+1), ldx21, tauq1(i),
306  $ x21(i+1,i+1), ldx21, work(ilarf) )
307  CALL zlacgv( q-i, x21(i,i+1), ldx21 )
308  c = sqrt( dznrm2( p-i, x11(i+1,i+1), 1 )**2
309  $ + dznrm2( m-p-i, x21(i+1,i+1), 1 )**2 )
310  phi(i) = atan2( s, c )
311  CALL zunbdb5( p-i, m-p-i, q-i-1, x11(i+1,i+1), 1,
312  $ x21(i+1,i+1), 1, x11(i+1,i+2), ldx11,
313  $ x21(i+1,i+2), ldx21, work(iorbdb5), lorbdb5,
314  $ childinfo )
315  END IF
316 *
317  END DO
318 *
319  RETURN
320 *
321 * End of ZUNBDB1
322 *
xerbla
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
zdrot
subroutine zdrot(N, ZX, INCX, ZY, INCY, C, S)
ZDROT
Definition: zdrot.f:98
zlarfgp
subroutine zlarfgp(N, ALPHA, X, INCX, TAU)
ZLARFGP generates an elementary reflector (Householder matrix) with non-negative beta.
Definition: zlarfgp.f:104
zlacgv
subroutine zlacgv(N, X, INCX)
ZLACGV conjugates a complex vector.
Definition: zlacgv.f:74
zlarf
subroutine zlarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
ZLARF applies an elementary reflector to a general rectangular matrix.
Definition: zlarf.f:128
zunbdb5
subroutine zunbdb5(M1, M2, N, X1, INCX1, X2, INCX2, Q1, LDQ1, Q2, LDQ2, WORK, LWORK, INFO)
ZUNBDB5
Definition: zunbdb5.f:156
dznrm2
real(wp) function dznrm2(n, x, incx)
DZNRM2
Definition: dznrm2.f90:90
Here is the call graph for this function:
Here is the caller graph for this function: