db/dea/slansy_8f_source.html

 *> \brief \b SLANSY returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a real symmetric matrix.

 *

 *  =========== DOCUMENTATION ===========

 *

 * Online html documentation available at

 *            http://www.netlib.org/lapack/explore-html/

 *

 *> \htmlonly

 *> Download SLANSY + dependencies

 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/slansy.f">

 *> [TGZ]</a>

 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/slansy.f">

 *> [ZIP]</a>

 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/slansy.f">

 *> [TXT]</a>

 *> \endhtmlonly

 *

 *  Definition:

 *  ===========

 *

 *       REAL             FUNCTION SLANSY( NORM, UPLO, N, A, LDA, WORK )

 *

 *       .. Scalar Arguments ..

 *       CHARACTER          NORM, UPLO

 *       INTEGER            LDA, N

 *       ..

 *       .. Array Arguments ..

 *       REAL               A( LDA, * ), WORK( * )

 *       ..

 *

 *

 *> \par Purpose:

 *  =============

 *>

 *> \verbatim

 *>

 *> SLANSY  returns the value of the one norm,  or the Frobenius norm, or

 *> the  infinity norm,  or the  element of  largest absolute value  of a

 *> real symmetric matrix A.

 *> \endverbatim

 *>

 *> \return SLANSY

 *> \verbatim

 *>

 *>    SLANSY = ( max(abs(A(i,j))), NORM = 'M' or 'm'

 *>             (

 *>             ( norm1(A),         NORM = '1', 'O' or 'o'

 *>             (

 *>             ( normI(A),         NORM = 'I' or 'i'

 *>             (

 *>             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'

 *>

 *> where  norm1  denotes the  one norm of a matrix (maximum column sum),

 *> normI  denotes the  infinity norm  of a matrix  (maximum row sum) and

 *> normF  denotes the  Frobenius norm of a matrix (square root of sum of

 *> squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.

 *> \endverbatim

 *

 *  Arguments:

 *  ==========

 *

 *> \param[in] NORM

 *> \verbatim

 *>          NORM is CHARACTER*1

 *>          Specifies the value to be returned in SLANSY as described

 *>          above.

 *> \endverbatim

 *>

 *> \param[in] UPLO

 *> \verbatim

 *>          UPLO is CHARACTER*1

 *>          Specifies whether the upper or lower triangular part of the

 *>          symmetric matrix A is to be referenced.

 *>          = 'U':  Upper triangular part of A is referenced

 *>          = 'L':  Lower triangular part of A is referenced

 *> \endverbatim

 *>

 *> \param[in] N

 *> \verbatim

 *>          N is INTEGER

 *>          The order of the matrix A.  N >= 0.  When N = 0, SLANSY is

 *>          set to zero.

 *> \endverbatim

 *>

 *> \param[in] A

 *> \verbatim

 *>          A is REAL array, dimension (LDA,N)

 *>          The symmetric matrix A.  If UPLO = 'U', the leading n by n

 *>          upper triangular part of A contains the upper triangular part

 *>          of the matrix A, and the strictly lower triangular part of A

 *>          is not referenced.  If UPLO = 'L', the leading n by n lower

 *>          triangular part of A contains the lower triangular part of

 *>          the matrix A, and the strictly upper triangular part of A is

 *>          not referenced.

 *> \endverbatim

 *>

 *> \param[in] LDA

 *> \verbatim

 *>          LDA is INTEGER

 *>          The leading dimension of the array A.  LDA >= max(N,1).

 *> \endverbatim

 *>

 *> \param[out] WORK

 *> \verbatim

 *>          WORK is REAL array, dimension (MAX(1,LWORK)),

 *>          where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,

 *>          WORK is not referenced.

 *> \endverbatim

 *

 *  Authors:

 *  ========

 *

 *> \author Univ. of Tennessee

 *> \author Univ. of California Berkeley

 *> \author Univ. of Colorado Denver

 *> \author NAG Ltd.

 *

 *> \ingroup realSYauxiliary

 *

 *  =====================================================================

       REAL             function slansy( norm, uplo, n, a, lda, work )

 *

 *  -- LAPACK auxiliary routine --

 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --

 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--

 *

       IMPLICIT NONE

 *     .. Scalar Arguments ..

       CHARACTER          norm, uplo

       INTEGER            lda, n

 *     ..

 *     .. Array Arguments ..

       REAL               a( lda, * ), work( * )

 *     ..

 *

 * =====================================================================

 *

 *     .. Parameters ..

       REAL               one, zero

       parameter( one = 1.0e+0, zero = 0.0e+0 )

 *     ..

 *     .. Local Scalars ..

       INTEGER            i, j

       REAL               absa, sum, value

 *     ..

 *     .. Local Arrays ..

       REAL               ssq( 2 ), colssq( 2 )

 *     ..

 *     .. External Functions ..

       LOGICAL            lsame, sisnan

       EXTERNAL           lsame, sisnan

 *     ..

 *     .. External Subroutines ..

       EXTERNAL           slassq, scombssq

 *     ..

 *     .. Intrinsic Functions ..

       INTRINSIC          abs, sqrt

 *     ..

 *     .. Executable Statements ..

 *

       IF( n.EQ.0 ) THEN

          VALUE = zero

       ELSE IF( lsame( norm, 'M' ) ) THEN

 *

 *        Find max(abs(A(i,j))).

 *

          VALUE = zero

          IF( lsame( uplo, 'U' ) ) THEN

             DO 20 j = 1, n

                DO 10 i = 1, j

                   sum = abs( a( i, j ) )

                   IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum

    10          CONTINUE

    20       CONTINUE

          ELSE

             DO 40 j = 1, n

                DO 30 i = j, n

                   sum = abs( a( i, j ) )

                   IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum

    30          CONTINUE

    40       CONTINUE

          END IF

       ELSE IF( ( lsame( norm, 'I' ) ) .OR. ( lsame( norm, 'O' ) ) .OR.

      $         ( norm.EQ.'1' ) ) THEN

 *

 *        Find normI(A) ( = norm1(A), since A is symmetric).

 *

          VALUE = zero

          IF( lsame( uplo, 'U' ) ) THEN

             DO 60 j = 1, n

                sum = zero

                DO 50 i = 1, j - 1

                   absa = abs( a( i, j ) )

                   sum = sum + absa

                   work( i ) = work( i ) + absa

    50          CONTINUE

                work( j ) = sum + abs( a( j, j ) )

    60       CONTINUE

             DO 70 i = 1, n

                sum = work( i )

                IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum

    70       CONTINUE

          ELSE

             DO 80 i = 1, n

                work( i ) = zero

    80       CONTINUE

             DO 100 j = 1, n

                sum = work( j ) + abs( a( j, j ) )

                DO 90 i = j + 1, n

                   absa = abs( a( i, j ) )

                   sum = sum + absa

                   work( i ) = work( i ) + absa

    90          CONTINUE

                IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum

   100       CONTINUE

          END IF

       ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN

 *

 *        Find normF(A).

 *        SSQ(1) is scale

 *        SSQ(2) is sum-of-squares

 *        For better accuracy, sum each column separately.

 *

          ssq( 1 ) = zero

          ssq( 2 ) = one

 *

 *        Sum off-diagonals

 *

          IF( lsame( uplo, 'U' ) ) THEN

             DO 110 j = 2, n

                colssq( 1 ) = zero

                colssq( 2 ) = one

                CALL slassq( j-1, a( 1, j ), 1, colssq(1), colssq(2) )

                CALL scombssq( ssq, colssq )

   110       CONTINUE

          ELSE

             DO 120 j = 1, n - 1

                colssq( 1 ) = zero

                colssq( 2 ) = one

                CALL slassq( n-j, a( j+1, j ), 1, colssq(1), colssq(2) )

                CALL scombssq( ssq, colssq )

   120       CONTINUE

          END IF

          ssq( 2 ) = 2*ssq( 2 )

 *

 *        Sum diagonal

 *

          colssq( 1 ) = zero

          colssq( 2 ) = one

          CALL slassq( n, a, lda+1, colssq( 1 ), colssq( 2 ) )

          CALL scombssq( ssq, colssq )

          VALUE = ssq( 1 )*sqrt( ssq( 2 ) )

       END IF

 *

       slansy = VALUE

       RETURN

 *

 *     End of SLANSY

 *

       END

slassq
subroutine slassq(n, x, incx, scl, sumsq)
SLASSQ updates a sum of squares represented in scaled form.
Definition: slassq.f90:126

scombssq
subroutine scombssq(V1, V2)
SCOMBSSQ adds two scaled sum of squares quantities
Definition: scombssq.f:60

sisnan
logical function sisnan(SIN)
SISNAN tests input for NaN.
Definition: sisnan.f:59

lsame
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53

slansy
real function slansy(NORM, UPLO, N, A, LDA, WORK)
SLANSY returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition: slansy.f:122