slqt04()

subroutine slqt04	(	integer	M,
		integer	N,
		integer	NB,
		real, dimension(6)	RESULT
	)

SLQT04

Purpose:

 SLQT04 tests SGELQT and SGEMLQT.

Parameters

[in]	M	M is INTEGER Number of rows in test matrix.
[in]	N	N is INTEGER Number of columns in test matrix.
[in]	NB	NB is INTEGER Block size of test matrix. NB <= Min(M,N).
[out]	RESULT	RESULT is REAL array, dimension (6) Results of each of the six tests below. RESULT(1) = | A - L Q | RESULT(2) = | I - Q Q^H | RESULT(3) = | Q C - Q C | RESULT(4) = | Q^H C - Q^H C | RESULT(5) = | C Q - C Q | RESULT(6) = | C Q^H - C Q^H |

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 72 of file slqt04.f.

      IMPLICIT NONE
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER M, N, NB, LDT
*     .. Return values ..
      REAL RESULT(6)
*
*  =====================================================================
*
*     ..
*     .. Local allocatable arrays
      REAL, ALLOCATABLE :: AF(:,:), Q(:,:),
     $  L(:,:), RWORK(:), WORK( : ), T(:,:),
     $  CF(:,:), DF(:,:), A(:,:), C(:,:), D(:,:)
*
*     .. Parameters ..
      REAL ONE, ZERO
      parameter( zero = 0.0, one = 1.0 )
*     ..
*     .. Local Scalars ..
      INTEGER INFO, J, K, LL, LWORK
      REAL   ANORM, EPS, RESID, CNORM, DNORM
*     ..
*     .. Local Arrays ..
      INTEGER            ISEED( 4 )
*     ..
*     .. External Functions ..
      REAL SLAMCH, SLANGE, SLANSY
      LOGICAL  LSAME
      EXTERNAL slamch, slange, slansy, lsame
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC  max, min
*     ..
*     .. Data statements ..
      DATA iseed / 1988, 1989, 1990, 1991 /
*
      eps = slamch( 'Epsilon' )
      k = min(m,n)
      ll = max(m,n)
      lwork = max(2,ll)*max(2,ll)*nb
*
*     Dynamically allocate local arrays
*
      ALLOCATE ( a(m,n), af(m,n), q(n,n), l(ll,n), rwork(ll),
     $           work(lwork), t(nb,n), c(m,n), cf(m,n),
     $           d(n,m), df(n,m) )
*
*     Put random numbers into A and copy to AF
*
      ldt=nb
      DO j=1,n
         CALL slarnv( 2, iseed, m, a( 1, j ) )
      END DO
      CALL slacpy( 'Full', m, n, a, m, af, m )
*
*     Factor the matrix A in the array AF.
*
      CALL sgelqt( m, n, nb, af, m, t, ldt, work, info )
*
*     Generate the n-by-n matrix Q
*
      CALL slaset( 'Full', n, n, zero, one, q, n )
      CALL sgemlqt( 'R', 'N', n, n, k, nb, af, m, t, ldt, q, n,
     $              work, info )
*
*     Copy R
*
      CALL slaset( 'Full', m, n, zero, zero, l, ll )
      CALL slacpy( 'Lower', m, n, af, m, l, ll )
*
*     Compute |L - A*Q'| / |A| and store in RESULT(1)
*
      CALL sgemm( 'N', 'T', m, n, n, -one, a, m, q, n, one, l, ll )
      anorm = slange( '1', m, n, a, m, rwork )
      resid = slange( '1', m, n, l, ll, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = resid / (eps*max(1,m)*anorm)
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute |I - Q'*Q| and store in RESULT(2)
*
      CALL slaset( 'Full', n, n, zero, one, l, ll )
      CALL ssyrk( 'U', 'C', n, n, -one, q, n, one, l, ll )
      resid = slansy( '1', 'Upper', n, l, ll, rwork )
      result( 2 ) = resid / (eps*max(1,n))
*
*     Generate random m-by-n matrix C and a copy CF
*
      DO j=1,m
         CALL slarnv( 2, iseed, n, d( 1, j ) )
      END DO
      dnorm = slange( '1', n, m, d, n, rwork)
      CALL slacpy( 'Full', n, m, d, n, df, n )
*
*     Apply Q to C as Q*C
*
      CALL sgemlqt( 'L', 'N', n, m, k, nb, af, m, t, nb, df, n,
     $             work, info)
*
*     Compute |Q*D - Q*D| / |D|
*
      CALL sgemm( 'N', 'N', n, m, n, -one, q, n, d, n, one, df, n )
      resid = slange( '1', n, m, df, n, rwork )
      IF( dnorm.GT.zero ) THEN
         result( 3 ) = resid / (eps*max(1,m)*dnorm)
      ELSE
         result( 3 ) = zero
      END IF
*
*     Copy D into DF again
*
      CALL slacpy( 'Full', n, m, d, n, df, n )
*
*     Apply Q to D as QT*D
*
      CALL sgemlqt( 'L', 'T', n, m, k, nb, af, m, t, nb, df, n,
     $             work, info)
*
*     Compute |QT*D - QT*D| / |D|
*
      CALL sgemm( 'T', 'N', n, m, n, -one, q, n, d, n, one, df, n )
      resid = slange( '1', n, m, df, n, rwork )
      IF( dnorm.GT.zero ) THEN
         result( 4 ) = resid / (eps*max(1,m)*dnorm)
      ELSE
         result( 4 ) = zero
      END IF
*
*     Generate random n-by-m matrix D and a copy DF
*
      DO j=1,n
         CALL slarnv( 2, iseed, m, c( 1, j ) )
      END DO
      cnorm = slange( '1', m, n, c, m, rwork)
      CALL slacpy( 'Full', m, n, c, m, cf, m )
*
*     Apply Q to C as C*Q
*
      CALL sgemlqt( 'R', 'N', m, n, k, nb, af, m, t, nb, cf, m,
     $             work, info)
*
*     Compute |C*Q - C*Q| / |C|
*
      CALL sgemm( 'N', 'N', m, n, n, -one, c, m, q, n, one, cf, m )
      resid = slange( '1', n, m, df, n, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 5 ) = resid / (eps*max(1,m)*dnorm)
      ELSE
         result( 5 ) = zero
      END IF
*
*     Copy C into CF again
*
      CALL slacpy( 'Full', m, n, c, m, cf, m )
*
*     Apply Q to D as D*QT
*
      CALL sgemlqt( 'R', 'T', m, n, k, nb, af, m, t, nb, cf, m,
     $             work, info)
*
*     Compute |C*QT - C*QT| / |C|
*
      CALL sgemm( 'N', 'T', m, n, n, -one, c, m, q, n, one, cf, m )
      resid = slange( '1', m, n, cf, m, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 6 ) = resid / (eps*max(1,m)*dnorm)
      ELSE
         result( 6 ) = zero
      END IF
*
*     Deallocate all arrays
*
      DEALLOCATE ( a, af, q, l, rwork, work, t, c, d, cf, df)
*
      RETURN

Here is the call graph for this function:

Here is the caller graph for this function: