LAPACK  3.10.0
LAPACK: Linear Algebra PACKage
zla_gbamv.f
Go to the documentation of this file.
1 *> \brief \b ZLA_GBAMV performs a matrix-vector operation to calculate error bounds.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download ZLA_GBAMV + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zla_gbamv.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zla_gbamv.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zla_gbamv.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE ZLA_GBAMV( TRANS, M, N, KL, KU, ALPHA, AB, LDAB, X,
22 * INCX, BETA, Y, INCY )
23 *
24 * .. Scalar Arguments ..
25 * DOUBLE PRECISION ALPHA, BETA
26 * INTEGER INCX, INCY, LDAB, M, N, KL, KU, TRANS
27 * ..
28 * .. Array Arguments ..
29 * COMPLEX*16 AB( LDAB, * ), X( * )
30 * DOUBLE PRECISION Y( * )
31 * ..
32 *
33 *
34 *> \par Purpose:
35 * =============
36 *>
37 *> \verbatim
38 *>
39 *> ZLA_GBAMV performs one of the matrix-vector operations
40 *>
41 *> y := alpha*abs(A)*abs(x) + beta*abs(y),
42 *> or y := alpha*abs(A)**T*abs(x) + beta*abs(y),
43 *>
44 *> where alpha and beta are scalars, x and y are vectors and A is an
45 *> m by n matrix.
46 *>
47 *> This function is primarily used in calculating error bounds.
48 *> To protect against underflow during evaluation, components in
49 *> the resulting vector are perturbed away from zero by (N+1)
50 *> times the underflow threshold. To prevent unnecessarily large
51 *> errors for block-structure embedded in general matrices,
52 *> "symbolically" zero components are not perturbed. A zero
53 *> entry is considered "symbolic" if all multiplications involved
54 *> in computing that entry have at least one zero multiplicand.
55 *> \endverbatim
56 *
57 * Arguments:
58 * ==========
59 *
60 *> \param[in] TRANS
61 *> \verbatim
62 *> TRANS is INTEGER
63 *> On entry, TRANS specifies the operation to be performed as
64 *> follows:
65 *>
66 *> BLAS_NO_TRANS y := alpha*abs(A)*abs(x) + beta*abs(y)
67 *> BLAS_TRANS y := alpha*abs(A**T)*abs(x) + beta*abs(y)
68 *> BLAS_CONJ_TRANS y := alpha*abs(A**T)*abs(x) + beta*abs(y)
69 *>
70 *> Unchanged on exit.
71 *> \endverbatim
72 *>
73 *> \param[in] M
74 *> \verbatim
75 *> M is INTEGER
76 *> On entry, M specifies the number of rows of the matrix A.
77 *> M must be at least zero.
78 *> Unchanged on exit.
79 *> \endverbatim
80 *>
81 *> \param[in] N
82 *> \verbatim
83 *> N is INTEGER
84 *> On entry, N specifies the number of columns of the matrix A.
85 *> N must be at least zero.
86 *> Unchanged on exit.
87 *> \endverbatim
88 *>
89 *> \param[in] KL
90 *> \verbatim
91 *> KL is INTEGER
92 *> The number of subdiagonals within the band of A. KL >= 0.
93 *> \endverbatim
94 *>
95 *> \param[in] KU
96 *> \verbatim
97 *> KU is INTEGER
98 *> The number of superdiagonals within the band of A. KU >= 0.
99 *> \endverbatim
100 *>
101 *> \param[in] ALPHA
102 *> \verbatim
103 *> ALPHA is DOUBLE PRECISION
104 *> On entry, ALPHA specifies the scalar alpha.
105 *> Unchanged on exit.
106 *> \endverbatim
107 *>
108 *> \param[in] AB
109 *> \verbatim
110 *> AB is COMPLEX*16 array, dimension ( LDAB, n )
111 *> Before entry, the leading m by n part of the array AB must
112 *> contain the matrix of coefficients.
113 *> Unchanged on exit.
114 *> \endverbatim
115 *>
116 *> \param[in] LDAB
117 *> \verbatim
118 *> LDAB is INTEGER
119 *> On entry, LDAB specifies the first dimension of AB as declared
120 *> in the calling (sub) program. LDAB must be at least
121 *> max( 1, m ).
122 *> Unchanged on exit.
123 *> \endverbatim
124 *>
125 *> \param[in] X
126 *> \verbatim
127 *> X is COMPLEX*16 array, dimension
128 *> ( 1 + ( n - 1 )*abs( INCX ) ) when TRANS = 'N' or 'n'
129 *> and at least
130 *> ( 1 + ( m - 1 )*abs( INCX ) ) otherwise.
131 *> Before entry, the incremented array X must contain the
132 *> vector x.
133 *> Unchanged on exit.
134 *> \endverbatim
135 *>
136 *> \param[in] INCX
137 *> \verbatim
138 *> INCX is INTEGER
139 *> On entry, INCX specifies the increment for the elements of
140 *> X. INCX must not be zero.
141 *> Unchanged on exit.
142 *> \endverbatim
143 *>
144 *> \param[in] BETA
145 *> \verbatim
146 *> BETA is DOUBLE PRECISION
147 *> On entry, BETA specifies the scalar beta. When BETA is
148 *> supplied as zero then Y need not be set on input.
149 *> Unchanged on exit.
150 *> \endverbatim
151 *>
152 *> \param[in,out] Y
153 *> \verbatim
154 *> Y is DOUBLE PRECISION array, dimension
155 *> ( 1 + ( m - 1 )*abs( INCY ) ) when TRANS = 'N' or 'n'
156 *> and at least
157 *> ( 1 + ( n - 1 )*abs( INCY ) ) otherwise.
158 *> Before entry with BETA non-zero, the incremented array Y
159 *> must contain the vector y. On exit, Y is overwritten by the
160 *> updated vector y.
161 *> \endverbatim
162 *>
163 *> \param[in] INCY
164 *> \verbatim
165 *> INCY is INTEGER
166 *> On entry, INCY specifies the increment for the elements of
167 *> Y. INCY must not be zero.
168 *> Unchanged on exit.
169 *>
170 *> Level 2 Blas routine.
171 *> \endverbatim
172 *
173 * Authors:
174 * ========
175 *
176 *> \author Univ. of Tennessee
177 *> \author Univ. of California Berkeley
178 *> \author Univ. of Colorado Denver
179 *> \author NAG Ltd.
180 *
181 *> \ingroup complex16GBcomputational
182 *
183 * =====================================================================
184  SUBROUTINE zla_gbamv( TRANS, M, N, KL, KU, ALPHA, AB, LDAB, X,
185  $ INCX, BETA, Y, INCY )
186 *
187 * -- LAPACK computational routine --
188 * -- LAPACK is a software package provided by Univ. of Tennessee, --
189 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
190 *
191 * .. Scalar Arguments ..
192  DOUBLE PRECISION ALPHA, BETA
193  INTEGER INCX, INCY, LDAB, M, N, KL, KU, TRANS
194 * ..
195 * .. Array Arguments ..
196  COMPLEX*16 AB( LDAB, * ), X( * )
197  DOUBLE PRECISION Y( * )
198 * ..
199 *
200 * =====================================================================
201 *
202 * .. Parameters ..
203  COMPLEX*16 ONE, ZERO
204  parameter( one = 1.0d+0, zero = 0.0d+0 )
205 * ..
206 * .. Local Scalars ..
207  LOGICAL SYMB_ZERO
208  DOUBLE PRECISION TEMP, SAFE1
209  INTEGER I, INFO, IY, J, JX, KX, KY, LENX, LENY, KD, KE
210  COMPLEX*16 CDUM
211 * ..
212 * .. External Subroutines ..
213  EXTERNAL xerbla, dlamch
214  DOUBLE PRECISION DLAMCH
215 * ..
216 * .. External Functions ..
217  EXTERNAL ilatrans
218  INTEGER ILATRANS
219 * ..
220 * .. Intrinsic Functions ..
221  INTRINSIC max, abs, real, dimag, sign
222 * ..
223 * .. Statement Functions
224  DOUBLE PRECISION CABS1
225 * ..
226 * .. Statement Function Definitions ..
227  cabs1( cdum ) = abs( dble( cdum ) ) + abs( dimag( cdum ) )
228 * ..
229 * .. Executable Statements ..
230 *
231 * Test the input parameters.
232 *
233  info = 0
234  IF ( .NOT.( ( trans.EQ.ilatrans( 'N' ) )
235  $ .OR. ( trans.EQ.ilatrans( 'T' ) )
236  $ .OR. ( trans.EQ.ilatrans( 'C' ) ) ) ) THEN
237  info = 1
238  ELSE IF( m.LT.0 )THEN
239  info = 2
240  ELSE IF( n.LT.0 )THEN
241  info = 3
242  ELSE IF( kl.LT.0 .OR. kl.GT.m-1 ) THEN
243  info = 4
244  ELSE IF( ku.LT.0 .OR. ku.GT.n-1 ) THEN
245  info = 5
246  ELSE IF( ldab.LT.kl+ku+1 )THEN
247  info = 6
248  ELSE IF( incx.EQ.0 )THEN
249  info = 8
250  ELSE IF( incy.EQ.0 )THEN
251  info = 11
252  END IF
253  IF( info.NE.0 )THEN
254  CALL xerbla( 'ZLA_GBAMV ', info )
255  RETURN
256  END IF
257 *
258 * Quick return if possible.
259 *
260  IF( ( m.EQ.0 ).OR.( n.EQ.0 ).OR.
261  $ ( ( alpha.EQ.zero ).AND.( beta.EQ.one ) ) )
262  $ RETURN
263 *
264 * Set LENX and LENY, the lengths of the vectors x and y, and set
265 * up the start points in X and Y.
266 *
267  IF( trans.EQ.ilatrans( 'N' ) )THEN
268  lenx = n
269  leny = m
270  ELSE
271  lenx = m
272  leny = n
273  END IF
274  IF( incx.GT.0 )THEN
275  kx = 1
276  ELSE
277  kx = 1 - ( lenx - 1 )*incx
278  END IF
279  IF( incy.GT.0 )THEN
280  ky = 1
281  ELSE
282  ky = 1 - ( leny - 1 )*incy
283  END IF
284 *
285 * Set SAFE1 essentially to be the underflow threshold times the
286 * number of additions in each row.
287 *
288  safe1 = dlamch( 'Safe minimum' )
289  safe1 = (n+1)*safe1
290 *
291 * Form y := alpha*abs(A)*abs(x) + beta*abs(y).
292 *
293 * The O(M*N) SYMB_ZERO tests could be replaced by O(N) queries to
294 * the inexact flag. Still doesn't help change the iteration order
295 * to per-column.
296 *
297  kd = ku + 1
298  ke = kl + 1
299  iy = ky
300  IF ( incx.EQ.1 ) THEN
301  IF( trans.EQ.ilatrans( 'N' ) )THEN
302  DO i = 1, leny
303  IF ( beta .EQ. 0.0d+0 ) THEN
304  symb_zero = .true.
305  y( iy ) = 0.0d+0
306  ELSE IF ( y( iy ) .EQ. 0.0d+0 ) THEN
307  symb_zero = .true.
308  ELSE
309  symb_zero = .false.
310  y( iy ) = beta * abs( y( iy ) )
311  END IF
312  IF ( alpha .NE. 0.0d+0 ) THEN
313  DO j = max( i-kl, 1 ), min( i+ku, lenx )
314  temp = cabs1( ab( kd+i-j, j ) )
315  symb_zero = symb_zero .AND.
316  $ ( x( j ) .EQ. zero .OR. temp .EQ. zero )
317 
318  y( iy ) = y( iy ) + alpha*cabs1( x( j ) )*temp
319  END DO
320  END IF
321 
322  IF ( .NOT.symb_zero)
323  $ y( iy ) = y( iy ) + sign( safe1, y( iy ) )
324 
325  iy = iy + incy
326  END DO
327  ELSE
328  DO i = 1, leny
329  IF ( beta .EQ. 0.0d+0 ) THEN
330  symb_zero = .true.
331  y( iy ) = 0.0d+0
332  ELSE IF ( y( iy ) .EQ. 0.0d+0 ) THEN
333  symb_zero = .true.
334  ELSE
335  symb_zero = .false.
336  y( iy ) = beta * abs( y( iy ) )
337  END IF
338  IF ( alpha .NE. 0.0d+0 ) THEN
339  DO j = max( i-kl, 1 ), min( i+ku, lenx )
340  temp = cabs1( ab( ke-i+j, i ) )
341  symb_zero = symb_zero .AND.
342  $ ( x( j ) .EQ. zero .OR. temp .EQ. zero )
343 
344  y( iy ) = y( iy ) + alpha*cabs1( x( j ) )*temp
345  END DO
346  END IF
347 
348  IF ( .NOT.symb_zero)
349  $ y( iy ) = y( iy ) + sign( safe1, y( iy ) )
350 
351  iy = iy + incy
352  END DO
353  END IF
354  ELSE
355  IF( trans.EQ.ilatrans( 'N' ) )THEN
356  DO i = 1, leny
357  IF ( beta .EQ. 0.0d+0 ) THEN
358  symb_zero = .true.
359  y( iy ) = 0.0d+0
360  ELSE IF ( y( iy ) .EQ. 0.0d+0 ) THEN
361  symb_zero = .true.
362  ELSE
363  symb_zero = .false.
364  y( iy ) = beta * abs( y( iy ) )
365  END IF
366  IF ( alpha .NE. 0.0d+0 ) THEN
367  jx = kx
368  DO j = max( i-kl, 1 ), min( i+ku, lenx )
369  temp = cabs1( ab( kd+i-j, j ) )
370  symb_zero = symb_zero .AND.
371  $ ( x( jx ) .EQ. zero .OR. temp .EQ. zero )
372 
373  y( iy ) = y( iy ) + alpha*cabs1( x( jx ) )*temp
374  jx = jx + incx
375  END DO
376  END IF
377 
378  IF ( .NOT.symb_zero )
379  $ y( iy ) = y( iy ) + sign( safe1, y( iy ) )
380 
381  iy = iy + incy
382  END DO
383  ELSE
384  DO i = 1, leny
385  IF ( beta .EQ. 0.0d+0 ) THEN
386  symb_zero = .true.
387  y( iy ) = 0.0d+0
388  ELSE IF ( y( iy ) .EQ. 0.0d+0 ) THEN
389  symb_zero = .true.
390  ELSE
391  symb_zero = .false.
392  y( iy ) = beta * abs( y( iy ) )
393  END IF
394  IF ( alpha .NE. 0.0d+0 ) THEN
395  jx = kx
396  DO j = max( i-kl, 1 ), min( i+ku, lenx )
397  temp = cabs1( ab( ke-i+j, i ) )
398  symb_zero = symb_zero .AND.
399  $ ( x( jx ) .EQ. zero .OR. temp .EQ. zero )
400 
401  y( iy ) = y( iy ) + alpha*cabs1( x( jx ) )*temp
402  jx = jx + incx
403  END DO
404  END IF
405 
406  IF ( .NOT.symb_zero )
407  $ y( iy ) = y( iy ) + sign( safe1, y( iy ) )
408 
409  iy = iy + incy
410  END DO
411  END IF
412 
413  END IF
414 *
415  RETURN
416 *
417 * End of ZLA_GBAMV
418 *
419  END
dlamch
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:69
xerbla
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
ilatrans
integer function ilatrans(TRANS)
ILATRANS
Definition: ilatrans.f:58
zla_gbamv
subroutine zla_gbamv(TRANS, M, N, KL, KU, ALPHA, AB, LDAB, X, INCX, BETA, Y, INCY)
ZLA_GBAMV performs a matrix-vector operation to calculate error bounds.
Definition: zla_gbamv.f:186