cchkbl()

subroutine cchkbl	(	integer	NIN,
		integer	NOUT
	)

CCHKBL

Purpose:

 CCHKBL tests CGEBAL, a routine for balancing a general complex
 matrix and isolating some of its eigenvalues.

Parameters

[in]	NIN	NIN is INTEGER The logical unit number for input. NIN > 0.
[in]	NOUT	NOUT is INTEGER The logical unit number for output. NOUT > 0.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 53 of file cchkbl.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            NIN, NOUT
*     ..
*
* ======================================================================
*
*     .. Parameters ..
      INTEGER            LDA
      parameter( lda = 20 )
      REAL               ZERO
      parameter( zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IHI, IHIIN, ILO, ILOIN, INFO, J, KNT, N,
     $                   NINFO
      REAL               ANORM, MEPS, RMAX, SFMIN, TEMP, VMAX
      COMPLEX            CDUM
*     ..
*     .. Local Arrays ..
      INTEGER            LMAX( 3 )
      REAL               DUMMY( 1 ), SCALE( LDA ), SCALIN( LDA )
      COMPLEX            A( LDA, LDA ), AIN( LDA, LDA )
*     ..
*     .. External Functions ..
      REAL               CLANGE, SLAMCH
      EXTERNAL           clange, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgebal
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, max, real
*     ..
*     .. Statement Functions ..
      REAL               CABS1
*     ..
*     .. Statement Function definitions ..
      cabs1( cdum ) = abs( real( cdum ) ) + abs( aimag( cdum ) )
*     ..
*     .. Executable Statements ..
*
      lmax( 1 ) = 0
      lmax( 2 ) = 0
      lmax( 3 ) = 0
      ninfo = 0
      knt = 0
      rmax = zero
      vmax = zero
      sfmin = slamch( 'S' )
      meps = slamch( 'E' )
*
   10 CONTINUE
*
      READ( nin, fmt = * )n
      IF( n.EQ.0 )
     $   GO TO 70
      DO 20 i = 1, n
         READ( nin, fmt = * )( a( i, j ), j = 1, n )
   20 CONTINUE
*
      READ( nin, fmt = * )iloin, ihiin
      DO 30 i = 1, n
         READ( nin, fmt = * )( ain( i, j ), j = 1, n )
   30 CONTINUE
      READ( nin, fmt = * )( scalin( i ), i = 1, n )
*
      anorm = clange( 'M', n, n, a, lda, dummy )
      knt = knt + 1
      CALL cgebal( 'B', n, a, lda, ilo, ihi, scale, info )
*
      IF( info.NE.0 ) THEN
         ninfo = ninfo + 1
         lmax( 1 ) = knt
      END IF
*
      IF( ilo.NE.iloin .OR. ihi.NE.ihiin ) THEN
         ninfo = ninfo + 1
         lmax( 2 ) = knt
      END IF
*
      DO 50 i = 1, n
         DO 40 j = 1, n
            temp = max( cabs1( a( i, j ) ), cabs1( ain( i, j ) ) )
            temp = max( temp, sfmin )
            vmax = max( vmax, cabs1( a( i, j )-ain( i, j ) ) / temp )
   40    CONTINUE
   50 CONTINUE
*
      DO 60 i = 1, n
         temp = max( scale( i ), scalin( i ) )
         temp = max( temp, sfmin )
         vmax = max( vmax, abs( scale( i )-scalin( i ) ) / temp )
   60 CONTINUE
*
      IF( vmax.GT.rmax ) THEN
         lmax( 3 ) = knt
         rmax = vmax
      END IF
*
      GO TO 10
*
   70 CONTINUE
*
      WRITE( nout, fmt = 9999 )
 9999 FORMAT( 1x, '.. test output of CGEBAL .. ' )
*
      WRITE( nout, fmt = 9998 )rmax
 9998 FORMAT( 1x, 'value of largest test error            = ', e12.3 )
      WRITE( nout, fmt = 9997 )lmax( 1 )
 9997 FORMAT( 1x, 'example number where info is not zero  = ', i4 )
      WRITE( nout, fmt = 9996 )lmax( 2 )
 9996 FORMAT( 1x, 'example number where ILO or IHI wrong  = ', i4 )
      WRITE( nout, fmt = 9995 )lmax( 3 )
 9995 FORMAT( 1x, 'example number having largest error    = ', i4 )
      WRITE( nout, fmt = 9994 )ninfo
 9994 FORMAT( 1x, 'number of examples where info is not 0 = ', i4 )
      WRITE( nout, fmt = 9993 )knt
 9993 FORMAT( 1x, 'total number of examples tested        = ', i4 )
*
      RETURN
*
*     End of CCHKBL
*

Here is the call graph for this function:

Here is the caller graph for this function: