#!/bin/csh
#*---------------------------------------------------------------------*/
#*    serrano/prgm/project/bigloo/distribution/install ...             */
#*                                                                     */
#*    Author      :  Manuel Serrano                                    */
#*    Creation    :  Fri Mar  5 13:32:49 1993                          */
#*    Last change :  Thu Jul  1 13:42:17 1993  (serrano)               */
#*                                                                     */
#*    On install bigloo (puisqu'il a ete boote)                        */
#*---------------------------------------------------------------------*/

#*---------------------------------------------------------------------*/
#*    Choose here your destination variable                            */
#*---------------------------------------------------------------------*/
set dest = $1

#*---------------------------------------------------------------------*/
#*    !!! WARNING !!! WARNING !!! WARNING !!! WARNING !!! WARNING !!!  */
#*    Don't edit after this line                                       */
#*---------------------------------------------------------------------*/

#*---------------------------------------------------------------------*/
#*    Les variables generees                                           */
#*---------------------------------------------------------------------*/
set version = "1.3"
set bin     = $dest/bin
set lib     = $dest/lib/bigloo/$version
set include = $lib
set man     = $dest/man/man1

set cc      = gcc

#*---------------------------------------------------------------------*/
#*    On installe les librairies                                       */
#*---------------------------------------------------------------------*/
if( -d $dest/lib/bigloo ) then
  \rm -rf $dest/lib/bigloo
endif

if( -d $lib ) then
  \rm -rf $lib
endif

mkdir $dest/lib/bigloo
mkdir $lib

#*---------------------------------------------------------------------*/
#*    On change les droits                                             */
#*---------------------------------------------------------------------*/
chmod -R a+rxw `pwd`

#*---------------------------------------------------------------------*/
#*    On construit le bigloo.h                                         */
#*---------------------------------------------------------------------*/
\rm -f $include/bigloo.h

cat distribution/bigloo.h.head >! $include/bigloo.h
echo \#define LIBRARY_DIR"()" \"$lib\" >> $include/bigloo.h
echo \#define INCLUDE_DIR"()" \"$include\" >> $include/bigloo.h
cat distribution/bigloo.h.tail >> $include/bigloo.h

install -c -o `whoami` lib/$version/bigloo.heap $lib/bigloo.heap
install -c -o `whoami` lib/$version/libbigloo.a $lib/libbigloo.a
install -c -o `whoami` lib/$version/libbigloo_u.a $lib/libbigloo_u.a

ranlib $lib/libbigloo.a
ranlib $lib/libbigloo_u.a

#*---------------------------------------------------------------------*/
#*    On installe la doc                                               */
#*---------------------------------------------------------------------*/
\rm -f $man/bigloo.1

install -c -o `whoami` documentation/bigloo.1 $man/bigloo.1
install -c -o `whoami` documentation/bigloo.ps $lib/bigloo.ps

#*---------------------------------------------------------------------*/
#*    On retouche le fichier de path et on recompile                   */
#*---------------------------------------------------------------------*/
\rm -f distribution/SITE
echo $dest > distribution/SITE

mv lib/$version/bigloo.h lib/$version/bigloo.h.old
cp $include/bigloo.h lib/$version/bigloo.h
	
( cd comptime$version;                                              \
  touch Engine/path.scm;                                            \
  ../bin/bigloo$version Engine/path.scm -cc $cc -O -A;              \
  $cc -O -o $bin/bigloo$version */*.o -L$lib -lbigloo -lm;          \
  strip $bin/bigloo$version )

(cd $bin; \rm -f bigloo; ln -s bigloo$version bigloo)

\rm -f distribution/SITE

mv lib/$version/bigloo.h.old lib/$version/bigloo.h

echo `pwd` > distribution/SITE

#*---------------------------------------------------------------------*/
#*    Voila, c'est fini                                                */
#*---------------------------------------------------------------------*/
rehash
echo "install done"
echo "-------------------------------"
