Using XML-RPC with Perl

XML-RPC HOWTO
Prev |  | Next

# 6. Using XML-RPC with Perl

Ken MacLeod has implemented XML-RPC for Perl. You can find his Frontier::RPC module at his website or through CPAN.

To install Frontier::RPC, download the package and compile it in the standard fashion:

    bash$ gunzip -c Frontier-RPC-0.07b1.tar.gz | tar xvf -
    bash$ cd Frontier-RPC-0.07b1
    bash$ perl Makefile.PL
    bash$ make
    bash$ make test
    bash$ su -c 'make install'

(The process will be slightly different on Windows systems, or if you don't have root access. Consult your Perl documentation for details.)

## 6.1. A Perl Client

The following program shows how to call an XML-RPC server from Perl:

    use Frontier::Client;

    # Make an object to represent the XML-RPC server.
    $server_url = 'http://xmlrpc-c.sourceforge.net/api/sample.php';
    $server = Frontier::Client->new(url => $server_url);

    # Call the remote server and get our result.
    $result = $server->call('sample.sumAndDifference', 5, 3);
    $sum = $result->{'sum'};
    $difference = $result->{'difference'};

    print "Sum: $sum, Difference: $difference\n";

## 6.2. A Stand-Alone Perl Server

The following program shows how to write an XML-RPC server in Perl:

    use Frontier::Daemon;

    sub sumAndDifference {
        my ($x, $y) = @_;
        return {'sum' => $x + $y, 'difference' => $x - $y};
    }

    # Call me as http://localhost:8080/RPC2
    $methods = {'sample.sumAndDifference' => \&sumAndDifference};
    Frontier::Daemon->new(LocalPort => 8080, methods => $methods)
        or die "Couldn't start HTTP server: $!";

## 6.3. A CGI-Based Perl Server

`Frontier::RPC2` doesn't provide built-in support for CGI-based servers. It does, however, provide most of the pieces you'll need.

Save the following code as `sumAndDifference.cgi` in your web server's `cgi-bin` directory. (On Unix systems, you'll need to make it executable by typing `chmod +x sumAndDifference.cgi`.)

    #!/usr/bin/perl -w

    use strict;
    use Frontier::RPC2;

    sub sumAndDifference {
        my ($x, $y) = @_;
        return {'sum' => $x + $y, 'difference' => $x - $y};
    }

    process_cgi_call({'sample.sumAndDifference' => \&sumAndDifference});

    #==========================================================================
    #  CGI Support
    #==========================================================================
    #  Simple CGI support for Frontier::RPC2. You can copy this into your CGI
    #  scripts verbatim, or you can package it into a library.
    #  (Based on xmlrpc_cgi.c by Eric Kidd <http://xmlrpc-c.sourceforge.net/>.)

    # Process a CGI call.
    sub process_cgi_call ($) {
        my ($methods) = @_;

        # Get our CGI request information.
        my $method = $ENV{'REQUEST_METHOD'};
        my $type = $ENV{'CONTENT_TYPE'};
        my $length = $ENV{'CONTENT_LENGTH'};

        # Perform some sanity checks.
        http_error(405, "Method Not Allowed") unless $method eq "POST";
        http_error(400, "Bad Request") unless $type eq "text/xml";
        http_error(411, "Length Required") unless $length > 0;

        # Fetch our body.
        my $body;
        my $count = read STDIN, $body, $length;
        http_error(400, "Bad Request") unless $count == $length;

        # Serve our request.
        my $coder = Frontier::RPC2->new;
        send_xml($coder->serve($body, $methods));
    }

    # Send an HTTP error and exit.
    sub http_error ($$) {
        my ($code, $message) = @_;
        print <<"EOD";
    Status: $code $message
    Content-type: text/html

    <title>$code $message</title>
    <h1>$code $message</h1>
    <p>Unexpected error processing XML-RPC request.</p>
    EOD
        exit 0;
    }

    # Send an XML document (but don't exit).
    sub send_xml ($) {
        my ($xml_string) = @_;
        my $length = length($xml_string);
        print <<"EOD";
    Status: 200 OK
    Content-type: text/xml
    Content-length: $length

    EOD
        # We want precise control over whitespace here.
        print $xml_string;
    }

You can copy the utility routines into your own CGI scripts.

Prev | Home | Next
A Sample API: `sumAndDifference` |  | Using XML-RPC with Python