100 REM THIS PROGRAM DESIGNS TWO-LAYER COAX-CORE SUPER-TRAPS OF VERY HIGH 
101 REM CHARACTERISTIC REACTANCE. IT WAS WRITTEN BY A.C. BUXTON, 2225 
102 REM WOODPARK RD, AKRON, OHIO, 44333. TELEPHONE 1-216-836-3854
110 REM THE PROGRAM IS FILED UNDER THE NAME "SUPERTRP"
120 CLS
130 PRINT "THERE ARE THREE CATEGORIES OF RG58 COAX CABLE ACCORDING TO ";
131 PRINT "BELDEN: RG58U (BELDEN 8240), RG58A/U (BELDEN 8259), AND RG58C/U ";
132 PRINT "(BELDEN 8262), WITH SLIGHTLY VARYING CENTER CONDUCTOR TYPES."
140 PRINT "RG58U HAS A SOLID CENTER CONDUCTOR. BOTH RG58A/U AND RG58C/U ";
141 PRINT "HAVE STRANDED CENTER CONDUCTORS WITH 19 STRANDS."
150 PRINT "THE DIAMETER OF THE CORE OF ALL THREE TYPES IS .116 INCHES ."
160 PRINT "THE STRANDED CENTER CONDUCTOR TYPES ARE MORE RUGGED AND ";
161 PRINT "PREFERABLE FOR MAKING TRAPS."
170 PRINT "THE CAPACITY BETWEEN WINDINGS, PF/FT, WHEN USED AS SUPERTRAP ";
171 PRINT "WINDINGS IS ABOUT THE SAME FOR ALL TYPES, 7.1 PF/FT."
180 INPUT "ENTER THE TYPE COAX FROM WHICH CORE WINDINGS WERE TAKEN";RG$
190 INPUT "ENTER THE DIAMETER OF THE COAX CORE, INCHES";DC
200 INPUT "ENTER THE DIAMETER OF THE COIL FORM, INCHES";DF
210 INPUT "ENTER THE CAPACITY BETWEEN THE TWO WINDINGS, PF/FT";C
220 INPUT "ENTER THE DESIRED TRAP RESONANT FREQUENCY, MHZ";FT
230 PI=3.141592654#
240 N1=5
250 FOR I=1 TO 10
260 D1=DF+DC
270 D2=D1+DC*3^.5
280 N2=N1-.95
290 L1= N1^2*D1^2/4/(4.5*D1+10*N1*DC)
300 L2= N2^2*D2^2/4/(4.5*D2+10*N2*DC)
310 KM=(D1/D2)^2*N2/N1
320 LT=L1+L2+2*KM*SQR(L1*L2)
330 CT=PI*D2*(N2-.05)/12*C/4+.21*D2
340 F=1000/2/PI/SQR(LT*CT)
350 N1=N1*F/FT
360 NEXT I
370 CLS
380 PRINT TAB(13);"TRAP RESONANT FREQUENCY,";INT(100*F+.5)/100;"MHZ"
390 PRINT TAB(13);"TYPE COAX FROM WHICH CORE WINDINGS WERE MADE, ";RG$
400 PRINT TAB(13);"NUMBER OF TURNS OF INNER WINDING, ";INT(100*N1+.5)/100;
401 PRINT "TURNS"
410 PRINT TAB(13);"NUMBER OF TURNS OF OUTER WINDING, ";INT(100*N2+.5)/100;
411 PRINT "TURNS"
420 PRINT TAB(13);"MUTUAL INDUCTANCE COUPLING COEFFICIENT BETWEEN LAYERS, ";
421 PRINT INT(100*KM+.5)/100
430 PRINT TAB(13);"DIAMETER OF THE CORE OF THE COAX,";DC;" INCHES"
440 PRINT TAB(13);"TOTAL LENGTH OF COAX CORE PER TRAP, ";
441 PRINT INT(10*PI*(N1*(D1+DC)+N2*(D2+DC))/12+.5)/10+.75;" FEET"
450 PRINT TAB(13);"LONGITUDINAL LENGTH OF THE INNER WINDING, ";
451 PRINT INT(100*N1*DC+.5)/100;" INCHES"
460 PRINT TAB(13);"DIAMETER OF THE FORM, "; INT(1000*DF+.5)/1000;" INCHES"
470 PRINT TAB(13);"DIAMETER OF COAX CORE, ";INT(1000*DC+.5)/1000;" INCHES"
480 PRINT TAB(13);"CAPACITANCE BETWEEN WINDING LAYERS, ";INT(10*C+.5)/10;
481 PRINT " PF/FT OF OUTER WINDING"
490 PRINT TAB(13);"TOTAL TRAP INDUCTANCE, ";INT(10*LT+.5)/10;"MICROHENRY"
500 PRINT TAB(13);"TOTAL TRAP CAPACITANCE, ";INT(10*CT+.5)/10;"PICOFARAD"
510 PRINT TAB(13);"TRAP CHARACTERISTIC REACTANCE,";INT(1000*SQR(LT/CT));"OHMS"
520 PRINT
530 PRINT TAB(15);"     FIG        SUMMARY OF                  SUPER-TRAP ";
531 PRINT "SPECIFICATIONS "
8990 END
9000 SAVE "SUPERTRP"
9010 END
	  

.