1020 'THE FOLLOWING IS AN ADAPTATION OF THE NU1N

1030 'VOICE CONTROL PROGRAM TO WORK ON THE

1040 'YAESU FT747GX TRANSCEIVER

1050 'ADAPTATION BY KC2NT

1060 GOTO 6010

1070 '--------FT747-CODE--------LINES 1070-1200

1080 OPEN "COM1:4800,N,8,2" AS #1: COM(1)ON

1140 PRINT#1,CMD$;

1180 FOR INDEX=1 TO 200: NEXT INDEX

1200 COM(1)OFF:CLOSE#1: RETURN

2000 '--------DEFAULT-FREQUENCIES--------LINES 2000-2070

2010 FREQ=28.125: GOTO 3010

2020 FREQ=24.8:GOTO 3010

2030 FREQ=21.05:GOTO 3010

2040 FREQ=18.0705:GOTO 3010

2050 FREQ=14.0275:GOTO 3010

2060 FREQ=10.1025:GOTO 3010

2070 FREQ=7.0275:GOTO 3010

2080 FREQ=3.5275:GOTO 3010

2090 FREQ=1.801:GOTO 3010

3000 --------FREQ-CALCULATIONS--------LINES 3000-3230

3010 CFREQ=FREQ*1000*10

3020 FREQ$=STR$(CFREQ)

3030 IF CFREQ < 100000! THEN FREQ$=STR$(0)+FREQ$ ELSE FREQ$="0"+FREQ$

3035 HZ$=MID$(FREQ$,8,2)

3040 KHZ$=MID$(FREQ$,6,2):HKHZ$=MID$(FREQ$,4,2)

3050 MHZ$=MID$(FREQ$,2,2)

3055 HZ=VAL(LEFT$(HZ$,1))*16+VAL(RIGHT$(HZ$,1))

3060 KHZ=VAL(LEFT$(KHZ$,1))*16+VAL(RIGHT$(KHZ$,1))

3070 HKHZ=VAL(LEFT$(HKHZ$,1))*16+VAL(RIGHT$(HKHZ$,1))

3080 MHZ=VAL(LEFT$(MHZ$,1))*16+VAL(RIGHT$(MHZ$,1))

3085 CMD$=CHR$(HZ)+CHR$(KHZ)+CHR$(HKHZ)+CHR$(MHZ)+CHR$(&HA)

3150 GOSUB 1080:RETURN

3160 FREQ=FREQ+.0001:GOSUB 3010:RETURN: 'UP 100HZ

3170 FREQ=FREQ+.001: GOSUB 3010:RETURN: 'UP 1 KHZ

3180 FREQ=FREQ+.005:GOSUB 3010:RETURN: 'UP 5 KHZ

3190 FREQ=FREQ+.01:GOSUB 3010:RETURN: 'UP 10 KHZ

3200 FREQ=FREQ-.0001:GOSUB 3010:RETURN: 'DOWN 100HZ

3210 FREQ=FREQ-.001:GOSUB 3010:RETURN: 'DOWN 1 KHZ

3220 FREQ=FREQ-.005:GOSUB 3010:RETURN: 'DOWN 5 KHZ

3230 FREQ=FREQ-.01:GOSUB 3010:RETURN: 'DOWN 10 KHZ

3240 '--------FREQUENCY-OPTIONS-------LINES 3240-3350

3250      CLS:OPT=0:O$=""

3260      LOCATE 2,33:PRINT"FREQUENCY OPTIONS"

3270      LOCATE 5,37:PRINT"1. UP 100 HZ"

3280      LOCATE 6,37:PRINT"2. UP 1 KHZ"

3290      LOCATE 7,37:PRINT"3. UP 5 KHZ"

3300      LOCATE 8,37:PRINT"4. UP 10 KHZ"

3310      LOCATE 10,37:PRINT"5. DOWN 100 HZ"

3320      LOCATE 11,37:PRINT"6. DOWN 1 KHZ"

3330      LOCATE 12,37: PRINT"7. DOWN 5 KHZ"

3340      LOCATE 13,37:PRINT"8. DOWN 10 KHZ"

3350      LOCATE 15,37:PRINT"9. MAIN MENU"

3360 LOCATE 18,35:PRINT "ENTER OPTION"

3370 WHILE((LEN(O$)<1) OR (VAL(O$)<1 OR VAL(O$)>9))

3380 O$=INKEY$

3390 WEND

3400 OPT=VAL(O$)

3410 IF OPT=9 THEN GOTO 6010

3420 ON OPT GOSUB 3160,3170,3180,3190,3200,3210,3220,3230

3430 GOTO 3250

3440 '--------BAND--------LINES 3440-3600

3450 CLS:OPT=0:O$=""

3460 LOCATE 2,35:PRINT "SELECT BAND"

3470 LOCATE 7,34:PRINT"1. 10 METERS"

3480 LOCATE 8,34:PRINT"2. 12 METERS"

3490 LOCATE 9,34:PRINT"3. 15 METERS"

3500 LOCATE 10,34:PRINT"4. 17 METERS"

3510 LOCATE 11,34:PRINT"5. 20 METERS"

3520 LOCATE 12,34:PRINT"6. 30  METERS"

3530 LOCATE 13,34:PRINT"7. 40 METERS"

3535 LOCATE 14,34:PRINT"8. 80 METERS"

3537 LOCATE 15,34:PRINT"9. 160 METERS"

3540 LOCATE 18,35:PRINT"ENTER OPTION"

3550 WHILE ((LEN(O$)<1) OR (VAL(O$)<1 OR VAL(O$)>9))

3560 O$=INKEY$

3570 WEND

3580 OPT=VAL(O$)

3590 ON OPT GOSUB 2010,2020,2030,2040,2050,2060,2070,2080,2090

3600 GOTO 6010

4000 '---------------KEY-PAD ENTRY---------------

4010 'E.G. "ONE FOUR POINT ZERO FIVE" FOR 14.05

4020        CLS

4030        LOCATE 2,33:PRINT "ENTER FREQUENCY"

4040        LOCATE 12,37: INPUT  "FREQUENCY",   FREQ

4050      GOSUB 3010:GOTO 6010

5000 '---------------KEY-PAD-ENTRY MENU---------------

5010 CLS: OPT=0: O$=""

5020 LOCATE 2,31:PRINT"KEY-PAD MENU OPTIONS"

5030 LOCATE 7,35:PRINT"1. KEYPAD FREQUENCY"

5040 '**LIST OTHER OPTIONS HERE**

5050 LOCATE 9,35:PRINT"2. MAIN MENU"

5060 LOCATE 18,35:PRINT"ENTER OPTION"

5070 WHILE(LEN(O$)<1) OR (VAL(O$)<1 OR VAL (O$)>2)

5080 O$=INKEY$

5090 WEND

5100 OPT=VAL(O$)

5110 IF OPT=1 THEN GOTO 4010

5120 IF OPT=2 THEN GOTO 6010

6000 '--------MAIN MENU--------LINES 3610-3740

6010 CLS:OPT=0: O$=""

6020 LOCATE 2,31:PRINT"MAIN MENU OPTIONS"

6030 LOCATE 7,35:PRINT"1. BAND SELECT"

6040 LOCATE 9,35:PRINT"2. FREQUENCY UP/DOWN"

6050 LOCATE 11,35:PRINT"3. KEYPAD ENTRY"

6060 LOCATE 14,35:PRINT"4. QUIT"

6070 LOCATE 18,35:PRINT"ENTER OPTION"

6080 WHILE (LEN(O$)<1):O$=INKEY$:WEND

6090 WHILE  VAL(O$)<1:O$=INKEY$:WEND

6100 WHILE VAL(O$)>4:O$=INKEY$:WEND

6110 OPT=VAL(O$)

6120 IF OPT=1 THEN GOTO 3450

6130 IF OPT=2 THEN GOTO 3250

6140 IF OPT=3 THEN GOTO 5010

6150 IF OPT=4 THEN CLS: END

.