# $Id: PKGBUILD 136826 2011-09-01 21:49:26Z allan $
# Maintainer: Allan McRae <allan@archlinux.org>
# Contributor: Jochem Kossen <j.kossen@home.nl>
# Contributor: pierce.jason [VL7]

pkgname=fakeroot
pkgver=1.18
pkgrel=1
pkgdesc="Gives a fake root environment, useful for building packages as a non-privileged user."
arch=('i686' 'x86_64')
license=('GPL')
url="http://packages.debian.org/fakeroot"
groups=('base-devel')
install=fakeroot.install
depends=('glibc' 'filesystem' 'sed' 'util-linux' 'sh')
ADDRB="coreutils, sed, util-linux"
options=('!libtool')
source=(http://ftp.debian.org/debian/pool/main/f/${pkgname}/${pkgname}_${pkgver}.orig.tar.bz2)
md5sums=('b0e7696460ee54bc378b9c89997f77c2')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr --libdir=/usr/lib${LIBDIRSUFFIX}/libfakeroot \
	--disable-static --with-ipc=sysv
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR=${pkgdir} install

  install -dm755 ${pkgdir}/etc/ld.so.conf.d/
  echo "/usr/lib${LIBDIRSUFFIX}/libfakeroot" > ${pkgdir}/etc/ld.so.conf.d/fakeroot.conf

  # install README for sysv/tcp usage
  install -Dm644 ${srcdir}/${pkgname}-${pkgver}/README ${pkgdir}/usr/share/doc/${pkgname}/README
}

.