@verb #8484:"update_login relogin" this none this rxdo #9988
@program #8484:"update_login relogin" this none this
caller != this && raise(E_PERM)
{person} = args
if (logininfo = listassoc(person, this.current_login))
  {person, fl, uname, pword, @stuff} = logininfo
  return
  return person:tell({"You have not logged in before. Please type:", "", "lj-login (LiveJournal username)"})
endif
clientver = this.clientversion
try
  result = this:send_request({{"mode", "login"}, {"user", uname}, {"hpassword", pword}, {"clientversion", clientver}, {"getpickws", "1"}})
except e (ANY)
  return person:tell({"LiveJournal returned the following error:", e[2]})
endtry
maxpic = toint(`listassoc("pickw_count", result)[2] ! ANY => 0')
pics = {}
if (maxpic)
  for pic in [1..maxpic]
    pics = {@pics, listassoc(tostr("pickw_", pic), result)[2]}
  endfor
endif
if (`msg = listassoc("message", result)[2] ! ANY')
  this:important_message(msg)
endif
maxjournal = toint(`listassoc("access_count", result)[2] ! ANY => 0')
journals = {}
if (maxjournal)
  for journal in [1..maxjournal]
    journals = {@journals, listassoc(tostr("access_", journal), result)[2]}
  endfor
endif
logininfo = {1, uname, pword, pics, journals}
if (i = listiassoc(person, this.current_login))
  this.current_login[i][2..$] = logininfo
else
  this.current_login = {@this.current_login, {person, @logininfo}}
endif
"Last modified by Dax (#789) on Tue May  3 14:09:37 2005 MDT."
.