@verb #4812:"notify*_bin*_direct notify*_direct*_bin" this none this rxdo #4812
@program #4812:"notify*_bin*_direct notify*_direct*_bin" this none this
"Copied from Norm (#4805):notify Feb 10 14:52:52 2000"
"Copied from Polymorph (#4871):notify Feb  6 17:15:15 2000"
"Copied from Paradox (#7122):notify Jan  7 14:28:08 2000"
"Copied from Generic Connectable Object (#24):notify by Slacker (#55)Dec 29 15:55:13 1999"
if (caller != this && !caller_perms():controls(this))
  "Never remove this check.  It is important, believe it or else."
  raise(E_PERM)
endif
if (args)
  render = this.output_rendering_object
  typeof(text = args[1]) == $STR && (text = {args[1]})
  ntext = {}
  for i in [1..length(text)]
    if (this.output_wrap)
      for line in (render:render(text[i]))
        ntext = {@ntext, @render:wrap(line)}
      endfor
    else
      ntext = {@ntext, @render:render(text[i])}
    endif
  endfor
  text = ntext
elseif (text = this.output_more_buffer)
  this.output_more_buffer = {}
  this.output_more_linesleft = this.output_more_pagelength
else
  return
endif
$code_utils:semaphore_enter("notify")
if (this.output_more_buffer)
  this.output_more_buffer = {@this.output_more_buffer, @text}
else
  text = typeof(text) != LIST ? {text} | text
  for i in [1..length(text)]
    typeof(tl = text[i]) == $LIST || (tl = {text[i]})
    for line in (tl)
      if (!this.output_more_pagelength || this.output_more_linesleft > 0)
        index(verb, "bin") || (line = encode_binary(line))
        line = $msg:process_notify(line, this.output_accent_mode)
        try
          set_connection_option(this, "binary", 1)
          notify(this, line + this.output_eol)
          set_connection_option(this, "binary", 0)
          this.output_more_linesleft = this.output_more_linesleft - 1
        except (E_INVARG)
          "You aren't connected?"
        endtry
      else
        this.output_more_buffer = {@this.output_more_buffer, line}
      endif
      $cmd_utils:suspend_if_needed()
    endfor
  endfor
  if (this.output_more_buffer)
    notify(this, tostr("--- More --- Type [enter], flush, or rest --- ", length(this.output_more_buffer), " lines left ---"))
  endif
endif
$code_utils:semaphore_exit("notify")
"Last modified by Dax (#789) on Tue May  3 14:03:28 2005 MDT."
.