@verb #4063:"receive_page record_page @recorded @pages" any any any rxdo #4063
@program #4063:"receive_page record_page @recorded @pages" any any any
"Copied from Cecil (#7407):receive_page Jul 16 09:19:27 2001"
if (verb[1..6] == "record")
  if (!callers())
    return "Oops, called from the commandline. Such is the life when you're combining callables and commandline verbs into one neat little package"
  elseif (caller != this)
    raise(E_PERM, "Uhh, go away!")
  endif
  if (typeof(args[1]) == $LIST)
    for line in (args[1])
      this:record(line)
    endfor
    return
  endif
  `this.recorded_pages ! E_PROPNF => add_property(this, "recorded_pages", {}, {this, "rc"})'
  this.recorded_pages = {@this.recorded_pages, {time(), tostr(@args)}}
elseif (verb[1] == "@")
  if (callers() || player != this)
    raise(E_PERM)
  endif
  player:tell("Displaying recorded pages:")
  time = -1
  for recorded in (this.recorded_pages)
    lasttime = time
    {time, line} = recorded
    if (time != lasttime)
      player:tell({"", player:ctime(time)})
    elseif (!time)
      player:tell("")
    endif
    player:tell(line)
  endfor
  player:tell("--- Done ---")
  if ($cmd_utils:yes_or_no("Would you like to clear the recorded pages?", 0))
    this.recorded_pages = {}
    player:tell("Recorded data cleared.")
  endif
elseif (verb[1..7] == "receive")
  if (length(args) < 2)
    args = {"%1", args[1]}
  endif
  args[1] = typeof(args[1]) == $LIST ? args[1] | {args[1]}
  for x in (args[1])
    index(x, "%1") && (p1 = 1)
  endfor
  if (!`p1 ! E_VARNF')
    args[1] = {"%N has a broken page message!", "Message from %n reading: %1"}
    player:tell("Hey! You, there! ", this:title(), " notices you've got a broken page message! ", $cecil_utils:pronoun(this, "They"), " still got your page, but most other people probably won't!")
    player:tell($cecil_utils:pronoun(this, "They"), " suggests you add \"It reads %1\" to the end of your page message. If you're really confused, just type \"@clearprop me.msg_page_origin\" and all your problems will go away.")
  endif
  for x in (args[1])
    line = $msg:substitute(x, args[2])
    this:connected() ? this:tell(line) | this:record_page(line)
  endfor
  return this:connected(0) ? player in this.gaglist ? 0 | 1 | 2
endif
"Last modified by Dax (#789) on Tue May  3 13:55:56 2005 MDT."
.