$ v = 'f$verify(0)'
$!********************************************************************
$! wilkinson
$! 1.5VMS
$! 1994/10/14 20:44   
$! gopher_root1:[gopher.g2.vms2_13]make.common,v
$! Exp
$!
$! Paul Lindner, University of Minnesota CIS.
$!
$! Copyright 1991, 1992 by the Regents of the University of Minnesota
$! see the file "Copyright" in the distribution for conditions of use.
$!********************************************************************
$! MODULE: make.common
$! make script common subroutine for VMS client, server, utiltities
$! Expected arguments:  P1 - TCP/IP agent to use
$!			P2 - DEBUG or NODEBUG (optional if P3 unspecified)
$!			P3 - CLIENT or SERVER or LOCALES
$!*********************************************************************
$! Revision History:
$! make.common,v
$! Revision 1.5VMS 1995/10/14 20:44    wilkinson
$! Rework for better operation
$!
$! Revision 1.4  1994/08/29  14:34:00  wilkinson
$! Fix output directories for P3=LOCALES
$!
$! Revision 1.3  1994/08/11  14:03:00  wilkinson
$! Suppress includes for MISC compilations
$!
$! Revision 1.2  1994/08/10  15:09:00  wilkinson
$! Move /include setup to MAKE.COMMON from COMPILE.COMMON
$! Move compilation DEFINE macros to MAKE.COMMON from COMPILE.COMMON
$!
$! Revision 1.1  1994/08/09  14:09:00  wilkinson
$! Initial revision for 2.0VMS-16
$!
$!********************************************************************/
$!
$ ON CONTROL_Y THEN GOTO CLEANUP
$ ON ERROR THEN GOTO CLEANUP
$!
$ agent == 0
$ IF P3 .EQS. "SUPPORT"
$ THEN
$  option == "NOTCPIP"
$  GOTO DoneTCPIP
$ ENDIF
$ IF P1 .EQS. ""
$ THEN
$ write sys$output "Acceptable TCP/IP agents are"
$ write sys$output " [1] MultiNet (default)"
$ write sys$output " [2] UCX"
$ write sys$output " [3] Wollongong"
$ if P3 .nes. "SERVER"
$ then
$ write sys$output " [4] CMUIP
$ write sys$output " [5] NETLIB
$ write sys$output " [6] TCPWARE
$ read sys$command/prompt="Agent [1,2,3,4,5,6] (RETURN = [1]) " agent
$ else
$ read sys$command/prompt="Agent [1,2,3] (RETURN = [1]) " agent
$ endif
$ ENDIF
$ if agent .eq. 1 .or. agent .eq. "" .or. p1 .eqs. "MULTINET" then -
    option == "MULTINET"
$ if agent .eq. 2 .or. p1 .eqs. "UCX" then option == "UCX"
$ if agent .eq. 3 .or. p1 .eqs. "WOLLONGONG" then option == "WOLLONGONG"
$ if P3 .nes. "SERVER"
$ then
$   if agent .eq. 4 .or. p1 .eqs. "CMUIP" then option == "CMUIP"
$   if agent .eq. 5 .or. p1 .eqs. "NETLIB" then option == "NETLIB"
$   if agent .eq. 6 .or. p1 .eqs. "TCPWARE" then option == "UCX"
$ endif
$DoneTCPIP:
$ if f$getsyi("HW_MODEL").ge.1024
$ then
$   hardware :== "AXP"
$ else
$   hardware :== "VAX"
$ endif
$ debugger == "NODEBUG"
$ usage == "CLIENT"
$!
$ lis     == "[."+hardware+".lis]"
$ testlis  = "[."+hardware+"]lis.dir"
$ exe     == "[."+hardware+".exe]"
$ testexe  = "[."+hardware+"]exe.dir"
$ obj     == "[."+hardware+".obj]"
$ testobj  = "[."+hardware+"]obj.dir"
$ inc == "[-],[-.object]"
$!
$ macros == "''option'=1"
$!
$ if P2 .EQS. "DEBUG"
$  then
$  macros == "''macros',DEBUGGING"
$  debugger == "DEBUG"
$  obj     == "[."+hardware+".dbg]"
$  testobj  = "[."+hardware+"]dbg.dir"
$  endif
$ if P3 .EQS. "MISC"
$  then
$  inc == "[]"
$  endif
$ if P3 .EQS. "SUPPORT"
$  then
$  inc == "''inc',[-.gopherd]"
$  macros == "''macros',SERVER,VMS_SERVER"
$  endif
$ if P3 .EQS. "SERVER"
$  then
$  usage == "SERVER"
$  inc == "''inc',[-.gopherd]"
$  macros == "''macros',SERVER,VMS_SERVER"
$  testobj  = "[-.GOPHERD''f$extract(1,f$length(testobj),testobj)'"
$  testexe  = "[-.GOPHERD''f$extract(1,f$length(testexe),testexe)'"
$  testlis  = "[-.GOPHERD''f$extract(1,f$length(testlis),testlis)'"
$  obj == "[-.GOPHERD''f$extract(1,f$length(obj),obj)'"
$  exe == "[-.GOPHERD''f$extract(1,f$length(exe),exe)'"
$  lis == "[-.GOPHERD''f$extract(1,f$length(lis),lis)'"
$  endif
$ if P3 .EQS. "LOCALES"
$  then
$  usage == "LOCALES"
$  testobj  = "[-''f$extract(1,f$length(testobj),testobj)'"
$  testexe  = "[-''f$extract(1,f$length(testexe),testexe)'"
$  testlis  = "[-''f$extract(1,f$length(testlis),testlis)'"
$  obj == "[-''f$extract(1,f$length(obj),obj)'"
$  exe == "[-''f$extract(1,f$length(exe),exe)'"
$  lis == "[-''f$extract(1,f$length(lis),lis)'"
$  endif
$!
$ if f$search("''testobj'") .eqs. "" then cr/dir 'obj'
$ if f$search("''testlis'") .eqs. "" then cr/dir 'lis'
$ if f$search("''testexe'") .eqs. "" then cr/dir 'exe'
$!
$ compiler == "VAX_C"
$ if f$trnlnm("VAXCMSG") .eqs. "DECC$MSG" .or. -
			f$trnlnm("DECC$CC_DEFAULT") .eqs. "/DECC"
$	then
$	compiler == "DEC_C"
$	if usage .eqs. "CLIENT"	  then macros == "''macros',__CURSES"
$	endif
$!
$ CLEANUP:
.