@verb #962:":dump" this none this rxdo #55
@program #962:":dump" this none this
{?indent = 0} = args
start_tag = tostr("<", this->name)
for x in (this->attributes)
  start_tag = tostr(start_tag, " ")
  start_tag = tostr(start_tag, x[1], "='", x[2], "'")
  $command_utils:Suspend_if_needed(0)
endfor
this->children && (start_tag = tostr($su:trimr(start_tag), ">"))
if (length(this->children) == 1 && typeof(this->children[1]) == $STR)
  return tostr(start_tag, this->children[1], "</", this->name, ">")
elseif (this->children)
  dump = {start_tag}
  for x in (this->children)
    if (typeof(x) == $STR)
      dump = {@dump, "  " + x}
    elseif (typeof(x) == WAIF)
      dump = {@dump, @x->dump(indent + !!(indent < 0))}
    endif
    $command_utils:Suspend_if_needed(0)
  endfor
  dump = {@dump, tostr("</", this->name, ">")}
else
  start_tag = tostr($su:trimr(start_tag), "/>")
  dump = {start_tag}
endif
if (indent > 0)
  for x in [1..length(dump)]
    dump[x] = tostr($string_utils:space(indent * 2), dump[x])
    $command_utils:Suspend_if_needed(0)
  endfor
endif
return dump
"Last modified by whiz (#3135) on Mon Aug 12 13:39:21 2002 MDT."
"This verb previously owned by manta (#7165), and chowned to $slacker upon dewizarding (Sat Aug 17 14:50:06 2002 MDT)."
"Last modified by Dax (#789) on Tue May  3 13:43:08 2005 MDT."
.