@verb #9321:"vs verbsearch @vs @verbsearch @which which" any any any rxd #1186
@program #9321:"vs verbsearch @vs @verbsearch @which which" any any any
contential_parentage = {}
if (argstr == "")
  player:tell("USAGE: #9321:vs @vs verbsearch @verbsearch which @which <search_word> [np]")
  return
endif
for z in (player.location.contents)
  if (z != player)
    contential_parentage = {@contential_parentage, @#1186:parents(z)}
  endif
endfor
for x in ({@#1186:parents(player), @#1186:parents(player.location), @contential_parentage, @`player.features ! E_PROPNF'})
  try
    for y in (x:verbs())
      if (match(y, "%(^%| %)" + args[1] + "%( %|%*%|$%)"))
        player:tell("Match! ", y, " on ", x, "-", x.name)
      elseif (index(y, args[1]) && args[$] != "np")
        player:tell("Potch! ", y, " on ", x, "-", x.name)
      endif
    endfor
  except (E_PERM)
    player:tell("Warning! ", x, " ", x.name, " does not let me see its verbs!")
  except (E_TYPE)
    player:tell("Warning! ", x, " ", x.name, " does not give a list of verbs!")
  endtry
endfor
player:tell("Search complete.")
"Last modified by Kagen (#1186) on Thu Jul 18 08:37:36 2002 MDT."
.