@verb #8:"re*move ta*ke g*et" any out of/from inside/from this rxdo #55
@program #8:"re*move ta*ke g*et" any out of/from inside/from this
if (!this.opened)
  $msg:mtell("closed")
elseif (this.dark)
  $msg:mtell("dark")
elseif ((dobj = this:match(dobjstr, player)) == $nothing)
  $msg:mtell("iobj_only", verb, prepstr, iobjstr)
elseif ($command_utils:object_match_failed(dobj, dobjstr))
elseif (!(dobj in this.contents))
  $msg:mtell("not_contain", iobj, dobj)
elseif (iobj.location != player && iobj.location != player.location)
  $msg:mtell("not_here", iobj)
else
  dobj:moveto(player)
  if (dobj.location == player)
    $msg:mtell("remove")
  else
    dobj:moveto(this.location)
    if (dobj.location == this.location)
      $msg:mtell("remove")
      $msg:mtell("fall_out")
    else
      $msg:mtell("remove_fail")
    endif
  endif
endif
"Last modified by manta (#7165) on Fri Oct 12 13:14:37 2001 MDT."
"This verb previously owned by manta (#7165), and chowned to $slacker upon dewizarding (Sat Aug 17 14:50:04 2002 MDT)."
"Last modified by Dax (#789) on Sat Aug 17 14:50:04 2002 MDT."
.