@verb #8756:"@toad*!!!" any any any rdo #8756
@program #8756:"@toad*!!!" any any any
"Copied from Generic Wizard (#17):@toad by Slacker (#55)Mar 15 20:21:43 2001"
"@toad[!][!][!] [player] [reason]"
""
"Permanently suspends a character."
""
"@toad    - toads."
"@toad!   - graylists"
"@toad!!  - blacklists"
"@toad!!! - redlists"
reason = `$su:from_list(args[2..$], " ") ! E_RANGE => $cmd_utils:read("a reason")'
listname = {"", "graylist", "blacklist", "redlist"}[length(`verb[6..$] ! E_RANGE => 0') + 1]
!player.wizard || player != this && raise(E_PERM)
if ($command_utils:player_match_failed(dobj = $string_utils:match_player(args[1]), args[1]))
  return
elseif (args[1] != dobj.name && !(args[1] in dobj.aliases) && args[1] != tostr(dobj))
  return player:tell("For safety reasons, you must enter the full name or an object number. [", $su:nn(dobj), "]")
elseif (dobj == player)
  return player:tell("Toading yourself would be a very bad idea.")
endif
if ($wiz_utils:rename_all_instances(dobj, "_disfunc", "toad_disfunc"))
  player:sub_tell("%d:_disfunc renamed.")
endif
if ($wiz_utils:rename_all_instances(dobj, "_destructor", "toad_destructor"))
  player:sub_tell("%d:_destructor renamed.")
endif
keeper = $cmd_utils:yn("Save this Toad in the Toad Jar?", 1)
$toad_jar.toads = {@$toad_jar.toads, {dobj, dobj.email_address, @reason ? {reason} | {}, time(), keeper}}
if (!(e = $wiz_utils:("unset_player" + (keeper ? "_fully" | ""))(dobj, $repo_man)))
  player:tell(e)
endif
try
  if (listname && !$login:(listname + "ed")(cname = $string_utils:connection_hostname(dobj.last_connect_place)))
    $login:(listname + "_add")(cname)
    player:notify(tostr("Site ", cname, " ", listname, "ed."))
  else
    cname = ""
  endif
except (E_PROPNF)
  cname = ""
endtry
prime = dobj.primary_character
seconds = dobj.second_characters
valid(prime) && player:tell("*** NOTE: ", dobj:nn(), " was a second to ", prime:nn(), "! ***")
seconds && player:tell("*** NOTE: ", dobj:nn(), " has the following seconds: ", $string_utils:nn_list(seconds), "! ***")
!dobj:isa($project) && chparent(dobj, $toad)
dobj.anchor = #-1
move(dobj, $toad_jar)
"Repo_Man can deal with him later."
subj = tostr("@toad ", dobj:nn())
msg = {"Reason: " + reason, "", "Connected from: ", $su:from_list(dobj:all_connect_places(), ", ")}
msg = {@msg, "", tostr("E-Mail: ", dobj.email_address), @cname ? {@$string_utils:capitalize(listname + "ed: ") + cname} | {}, @reason ? {reason} | {}, keeper ? tostr("Keeping the Toad in the Toad Jar (", $toad_jar, ")") | "This Toad will be recycled (but still logged in $toad_jar.toads)"}
valid(prime) && (msg = {@msg, "", "Primary Character: " + prime:nn()})
seconds && (msg = {@msg, "", "Secondary Characters:", $string_utils:nn_list(seconds)})
$mail_agent:send_message(player, $toad_log, subj, msg)
dobj.criminal_record = {@dobj.criminal_record, tostr("TOADED: By ", player, " on ", ctime(), " for ", reason)}
.