@verb #84:"tell_general" this none this rxdo #60
@program #84:"tell_general" this none this
{object} = args
mods = {}
if (player.user:controls(object))
  player:tell("<FORM METHOD=\"POST\"><INPUT TYPE=\"checkbox\" NAME=\"r\"", object.r ? " CHECKED" | "", "><B>R</B>eadable <INPUT TYPE=\"checkbox\" NAME=\"w\"", object.w ? " CHECKED" | "", "><B>W</B>ritable <INPUT TYPE=\"checkbox\" NAME=\"f\"", object.f ? " CHECKED" | "", "><B>F</B>ertile <INPUT TYPE=\"hidden\" NAME=\"chmod\" VALUE=\"on\"><INPUT TYPE=\"submit\" VALUE=\"Chmod\"></FORM>")
else
  object.r && (mods = {"readable"})
  object.w && (mods = {@mods, "writable"})
  object.f && (mods = {@mods, "fertile"})
endif
is_player(object) && (mods = {@mods, "player"})
object.programmer && (mods = {@mods, "programmer"})
object.wizard && (mods = {@mods, "wizard"})
player:tell("<FORM METHOD=\"POST\">")
mods && player:tell("<I>", $string_utils:from_list(mods, " | "), "</I><BR>")
if (player.user.wizard)
  player:tell("Owned by <INPUT TYPE=\"text\" NAME=\"chown\" VALUE=\"", $html_utils:literal_text($su:nn(object.owner)), "\"> <INPUT TYPE=\"submit\" VALUE=\"Chown\">")
else
  player:tell("Owned by ", $www:link(object.owner), ".")
endif
player:tell("<BR>Location ", $www:link(object.location), ".")
player:tell("<BR>Child of ", this:link(parent(object)), ".")
if (k = length(children(object)))
  player:tell("<BR>Has <A HREF=\"/", toint(object), "/setup/children\">", k, k == 1 ? " child" | " children", "</A>.")
  if (k <= 4)
    kids = children(object)
    for k in [1..k]
      kids[k] = this:link(kids[k])
    endfor
    player:tell(" (", $string_utils:from_list(kids, ", "), ")")
  endif
else
  player:tell("<BR>Has no children.")
endif
if (k = length(object.contents))
  player:tell("<BR>Contains <A HREF=\"/", toint(object), "/setup/contents\">", k, k == 1 ? " object" | " objects", "</A>.")
  if (k <= 4)
    kids = object.contents
    for k in [1..k]
      kids[k] = this:link(kids[k])
    endfor
    player:tell(" (", $string_utils:from_list(kids, ", "), ")")
  endif
else
  player:tell("<BR>Has no contents.")
endif
player:tell("</FORM>")
"Last modified by Dax (#789) on Tue May  3 14:09:30 2005 MDT."
.