@verb #8438:"@check-machine @clear-machine" any none none rdo #8438
@program #8438:"@check-machine @clear-machine" any none none
if (player.answering_machine == {})
  return player:tell("Your answering machine has no recored messages.")
endif
if (verb[2..6] == "check")
  if (!dobjstr)
    count = 0
    msgs = {}
    for msg in (player.answering_machine)
      count = count + 1
      msgs = {@msgs, {msg[4] == 1 ? " " | "*", count, $string_utils:nn(msg[1]), tostr($time_utils:ampm(player:ctime(msg[2])), " ", $time_utils:mmddyy(msg[2]))}}
      $command_utils:suspend_if_needed(0)
    endfor
    return player:tellcolumns(1, {1, 1, 1, 1}, {"", "#", "Name", "When"}, @msgs)
  elseif (dobjstr == "all")
    for m in [1..length(player.answering_machine)]
      msg = player.answering_machine[m]
      player.answering_machine[m][4] = 1
      player:tell("From: ", $string_utils:nn(msg[1]), "   Time: ", $time_utils:ampm(player:ctime(msg[2])), ":")
      player:tell(msg[3])
      suspend(0)
    endfor
    return
  elseif (`NUM = toint(dobjstr) ! ANY => 0')
    if (!`player.answering_machine[NUM] ! ANY => 1')
      return player:tell("No message numbered ", tostr(NUM), ".")
    else
      player.answering_machine[NUM][4] = 1
      msg = player.answering_machine[NUM]
      player:tell("From: ", $string_utils:nn(msg[1]), " Time ", $time_utils:ampm(player:ctime(msg[2])), ":")
      return player:tell(msg[3])
    endif
  else
    return player:tell("Syntax: ", verb, " [all | message number]")
  endif
elseif (verb[2..6] == "clear")
  if (!dobjstr || dobjstr == "all")
    player:tell("Clear all messages on your machine?")
    player.answering_machine = $command_utils:yes_or_no() ? {} | player.answering_machine
    return player:tell(player.answering_machine == {} ? "Machine cleared." | "Aborted.")
  elseif (`toint(dobjstr) ! ANY => 0')
    NUM = `toint(dobjstr) ! ANY => 0'
    if (NUM == 0)
      return player:tell("Syntax: ", verb, " [all | message number]")
    elseif (`player.answering_machine[NUM] ! ANY => 0')
      player.answering_machine = setremove(player.answering_machine, player.answering_machine[NUM])
      return player:tell("Message removed.")
    else
      return player:tell("There is no message numbered ", tostr(NUM), ".")
    endif
  endif
endif
"Last modified by Dax (#789) on Tue May  3 14:14:41 2005 MDT."
.