@verb #8431:"info" none none none rdo #8431
@program #8431:"info" none none none
"Copied from Leo (#8383):info Jul  4 22:41:38 1997"
"Copied from Dave (asleep) (#7418):info Jun 22 08:23:42 1997"
"Copyright (C) by Dave (#7418)"
""
"   Returns a short paragraph of interesting info about the players"
" on the MOO, player ranking and garbage stats."
"							-- Dave"
males = {}
females = {}
its = {}
for person in (players())
  $command_utils:suspend_if_needed()
  if (person.gender == "male")
    males = {@males, person}
  elseif (person.gender == "female")
    females = {@females, person}
  else
    its = {@its, person}
  endif
endfor
player:tell(tostr(length(players())) + " players: " + tostr(length(males)) + " males; " + tostr(length(females)) + " females; " + tostr(length(its)) + " other.")
player:tell("Last obj #: " + tostr(max_object()) + "(" + max_object():title() + ")")
player:tell("Last player: " + (lastdude = players()[$]):title() + "(" + lastdude.name + "(" + tostr(lastdude) + "))")
player:tell("Rank: " + tostr(this in players()) + ", within the top " + tostr(tofloat(this in players()) * 100.0 / tofloat(length(players()))) + "%.")
poubelle = tofloat(length(children($garbage)))
stuff = tofloat(max_object()) - poubelle
player:tell("Number of garbage objects: " + tostr(poubelle) + " - " + tostr(garb = poubelle * 100.0 / tofloat(max_object())) + "%")
t = time()
player:tell("Number of used objects:    " + tostr(stuff) + " - " + tostr(stuff * 100.0 / tofloat(max_object())) + "%")
newmax = 0
newmin = 0
if (garb < this.garbmin[1])
  this.garbmin = {garb, t}
  newmin = 1
elseif (garb > this.garbmax[1])
  this.garbmax = {garb, t}
  newmax = 1
endif
player:tell("The largest garbage percentage recorded was " + tostr(this.garbmax[1]) + "% on " + tostr(ctime(this.garbmax[2])) + (newmax ? ".  <--- NEW!!" | "."))
player:Tell("The smallest garbage percentage recorded was " + tostr(this.garbmin[1]) + "% on " + tostr(ctime(this.garbmin[2])) + (newmin ? ".  <--- NEW!!" | "."))
"Last modified by Slacker (#55) on Tue Aug 20 11:54:20 2002 MDT."
.