@verb #81:"GET HEAD" any any any rdo #55
@program #81:"GET HEAD" any any any
{?what = "", ?version = "HTTP/0.9", @rest} = args
if (index(what, "HTTP") == 1)
  version = what
  what = ""
endif
this.version = version
this.request = "GET"
this.url = what
{object, parameters} = $www:parse_URL(what)
this.object = object
this.parameters = parameters
for x in ({@this.daemon.spies, @this.daemon.spies_lowfat})
  x:tell(`$string_utils:connection_hostname(connection_name(this)) ! ANY', " (", this.user, ")", " wants ", what, ", got ", object, ":(GET:\"", parameters, "\").")
endfor
if (valid(object) && object:isa($fastweb) && (!parameters || parameters[1] == "?"))
  "FastWeb objects receive limited by fast service."
  this.version = version = "HTTP/0.9"
endif
if (version == "HTTP/0.9")
  if (`$login:blacklisted(host = $su:connection_hostname(connection_name(this))) ! E_INVARG')
    return $www.error:unauthorized()
  elseif ($login:graylisted(`host ! E_VARNF => ""'))
    if (time() > $wiz_utils.last_web_alert + 60 * 2)
      $wiz_utils.last_web_alert = time()
      $wiz_utils:guard_alert("Web-Connection from graylisted site (", host, ") by ", this.user:nn(), " to ", this.url)
    endif
  endif
  $www:serve_page(object, parameters, "")
  this:boot()
else
  "HTTP/1.0 and above send a blank line at the end of the headers.  We'll pick it up then."
endif
"Last modified by Dax (#789) on Fri Dec 16 03:40:35 2005 MST."
.