@verb #80:"parse_URL" this none this rxdo #60
@program #80:"parse_URL" this none this
{what} = args
what && what[1] == "/" && (what[0..1] = "")
if (what == "robots.txt")
  return {$www, "robots.txt"}
elseif (what == "favicon.ico")
  return {$favicon, ""}
elseif (`what[1..3] == "%7E" ! E_RANGE')
  what[1..3] = "~"
endif
separator = $math_utils:min_positive(index(what, "/"), index(what, "?"), index(what, "!"), index(what, "."), index(what, ":"), index(what, ","), index(what, ";"), index(what, "%"))
objstring = what[1..separator ? separator - 1 | $]
parameters = separator ? what[separator..$] | ""
if (!objstring)
  object = $splash
elseif ((o = toobj(objstring)) != #0)
  object = $recycler:valid(o) ? o | #-1
elseif (objstring == "0")
  object = #0
elseif (typeof(`o = #0.(objstring) ! E_PROPNF') == $OBJ)
  object = o
elseif (`objstring[1] == "~" && valid(o = $string_utils:match_player(objstring[2..$])) ! E_RANGE => 0')
  object = o
else
  object = #-1
endif
return {object, parameters}
"Last modified by Dax (#789) on Tue May  3 13:47:07 2005 MDT."
.