@verb #80:"_kick" this none this rxdo #55
@program #80:"_kick" this none this
"Begin generic security check (_kick)"
if (verb == "_kick" && !args[1]:isa(this))
  raise(E_INVARG, "Illegal object", args[1])
  return E_INVARG
endif
"End generic security check (_kick)"
"Hoof dead connections."
for x in (connected_players())
  if (x:isa($webber) && connected_seconds(x) > 30)
    x:boot()
    suspend(1)
  endif
endfor
"Clear out all the unconnected webbers."
for x in (this.owned_objects)
  suspend(0)
  if (valid(x) && x:isa($webber) && !x:connected())
    this.available = setremove(this.available, x)
    this.in_use = setremove(this.in_use, x)
    set_player_flag(x, 0)
    $recycler:recycle(x)
  endif
endfor
"And rebuild the webbers."
for x in [1..this.min_free_cons]
  suspend(0)
  this:new_connection_obj()
endfor
"Rebuild the .url prop."
port = this.port
if (port == 80)
  this.url = tostr("http://www.", $site, "/")
else
  this.url = tostr("http://www.", $site, ":", port, "/")
endif
"Update the desubst list from the subst list."
this.subst = $list_utils:sort_alist(this.subst)
this.desubst = this.desubst_single = {}
for x in (this.subst)
  this.desubst = {@this.desubst, {x[2], x[1]}}
  length(x[2]) == 1 && (this.desubst_single = {@this.desubst_single, {x[2], x[1]}})
  $command_utils:suspend_if_needed()
endfor
"Last modified by manta (#7165) on Tue Jul 23 11:18:22 2002 MDT."
"This verb previously owned by manta (#7165), and chowned to $slacker upon dewizarding (Sat Aug 17 14:50:05 2002 MDT)."
"Last modified by Dax (#789) on Sat Aug 17 14:50:05 2002 MDT."
.