@verb #8084:"tellColumns*_suspended" this none this rdo #8084
@program #8084:"tellColumns*_suspended" this none this
"Copied from Lao-Tzu (#8084):tellColumns by Hacker (#60)Aug 15 20:26:55 2001"
"Copied from Generic WWW connection (#81):tellColumns by Hacker (#60)Aug 15 20:26:42 2001"
"Performs the same function as $player:TellColumns, but the output is tailored to the type of browser that the web user has."
if (typeof(args[1]) == $INT)
  if (args[1] in {1, 2, 3})
    justify = $string_utils:space(length(args[2]), "lcr"[args[1]])
    args = listdelete(args, 1)
  else
    raise(E_INVARG, "Justify parameter must be 1,2,3 or a string")
  endif
elseif (typeof(args[1]) == $STR)
  justify = args[1]
  args = listdelete(args, 1)
else
  justify = $string_utils:space(length(args[1]), "l")
endif
"Assume that the browser can display tables."
out = {}
"We don't care about the ratios"
args = listdelete(args, 1)
for i in [1..length(args)]
  row = args[i]
  block = "<TR>"
  if (typeof(row) == $STR)
    block = block + "<td colspan=" + tostr(length(justify)) + "><hr /></td>"
  else
    for j in [1..length(row)]
      col = row[j]
      td = i == 1 ? {"<TH>", "</TH>"} | {{"<TD>", "<TD ALIGN=\"center\">", "<TD ALIGN=\"right\">"}[justify[j] in {"l", "c", "r"}], "</TD>"}
      block = tostr(block, td[1], col, td[2])
    endfor
  endif
  out = {@out, block + "</TR>"}
  $command_utils:suspend_if_needed()
endfor
this:tell($su:from_list({"<table border='0'>", @out, "</table>"}, ""))
"Last modified by Dax (#789) on Tue May  3 13:43:12 2005 MDT."
.