@verb #7854:"@where2" any any any rxdo #7854
@program #7854:"@where2" any any any
"Copied from Generic Player (#12):@where by Slacker (#55)Aug 20 23:15:47 1998"
"A verb that provides alternative info to @who."
if (argstr in {"am I?", "am I"})
  args = {"me"}
endif
set_task_perms(this)
if (caller == this && (plyrs = args ? listdelete($command_utils:player_match_result($string_utils:match_player(args), args), 1) | connected_players()))
  loc = {}
  for x in (plyrs)
    try
      loc = {@loc, valid(x) ? x.location:msg_who_location(x) | "<Nowhere>"}
    except (ANY)
      loc = {@loc, "!Doh! Broken verb . . ."}
    endtry
  endfor
  $tcm || (plyrs = $list_utils:sort(plyrs, loc))
  "  see_priv = player:isa($guardian);"
  lines = {}
  for dude in (plyrs)
    try
      rank = dude:rank(6)
      where = ``dude.location:msg_who_location(dude) ! E_INVIND => "&lt;nowhere&gt;"' ! E_VERBNF => dude.location:title()'
      warned = player:isa($guardian) || "" && (`dude.warned ! E_PROPNF => 0' ? "w" | " ")
      lines = {@lines, {dude:title(), tostr(dude, warned, " "), rank, where, tostr(dude.location)}}
    except q (ANY)
      player:tell("--player ", dude, " in ", dude.location, " has a borked verb--")
    endtry
    $command_utils:suspend_if_needed()
  endfor
  player:tellcolumns("13113", {1, 1, 1, 1, 1}, {"Player", "", "Rank", "Location", ""}, @lines)
  player:tell("Total number of ", args ? "selected" | "connected", " players: ", length(plyrs), "   Time: ", ctime()[12..16])
endif
"Last modified by Dax (#789) on Thu May  5 15:25:41 2005 MDT."
.