@verb #7854:"@mm" none none none rdo #7854
@program #7854:"@mm" none none none
"Copied from Generic Player (#12):@Nn by manta (#7165)Feb  1 15:10:24 2001"
"@nn - Next New"
"Read the next new message on you or your subscribed mailing lists."
set_task_perms(player)
skipstr = ""
who = valid(x = `this.mail_identity ! E_PROPNF => #-1') ? x | this
cm = who.current_message
cm[1..2] = {{this, @cm[1..2]}}
for n in (cm)
  if (!$mail_agent:is_recipient(n[1]))
    this:tell("Removing bogus recipient: ", $string_utils:nn(n[1]))
    who.current_message = setremove(who.current_message, n)
    continue
  elseif (new = n[1]:length_date_gt(n[3]))
    next = n[1]:get_num(n[1]:length_all_msgs() - new + 1)
    who:set_current_folder(folder = n[1])
    "Initial Kill List hack by BenC"
    for dumbass in (player._kill)
      if (next in folder:from_msg_seq(dumbass))
        skipstr = "Note: Message " + tostr(next) + " skipped.  Author is on your message kill list."
        next = next + 1
      endif
    endfor
    who._mail_task = task_id()
    cur = folder:display_seq_full({next, next + 1}, tostr("Message %d", " on ", $mail_agent:name(folder), ":"))
    this:tell(skipstr)
    who:set_current_message(folder, @cur)
    return
  endif
endfor
this:tell($code_utils:verb_or_property(this, "silly_news_messages")[random($)])
.