@verb #755:"_constructor" this none this rxdo #789
@program #755:"_constructor" this none this
"When someone creates this room, it will automatically create and configire the buffer and transcript."
"Begin generic security check (_constructor)"
if (verb == "_constructor" && caller_perms() != #-1)
  raise(E_PERM)
  return E_PERM
endif
"End generic security check (_constructor)"
if (caller_perms() != #-1)
  raise(E_PERM)
endif
player:tell("Your new room's URL is: ", $www.url, toint(args[1]))
!caller:isa(#756) && (args[1].users = {})
args[1].buffer = #-1
args[1].transcript = #-1
person = player:isa($webber) ? player.user | player
fork (1)
  player:tell("Creating a buffer and a transcript for your new conference room...")
  if (!person:controls(parent(args[1]).buffer) && !parent(args[1]).buffer.f || (!person:controls(parent(args[1]).transcript) && !parent(args[1]).transcript.f))
    player:tell("Unable to complete action: buffer or transcript is not fertile.")
    return
  endif
  object = $recycler:create(parent(args[1]).buffer, person)
  if (typeof(object) == $OBJ)
    $building_utils:set_names(object, "buffer")
    object:moveto(args[1])
    object.key = #-1
    args[1].buffer = object
  else
    player:tell("To properly activate your new web conference room, you must first make a ", parent(args[1]).buffer, ", drop it, and set your room's .buffer prop to its object #.")
  endif
  object = $recycler:create(parent(args[1]).transcript, person)
  if (typeof(object) == $OBJ)
    $building_utils:set_names(object, "transcript")
    object:moveto(args[1])
    object.key = #-1
    args[1].transcript = object
  else
    player:tell("If you want to keep a transcript, you must create ", parent(args[1]).transcript, ", drop it, and set your room's .transcript prop to its object #.")
  endif
  player:tell("Setup is complete.  For more information on how to use your room, read its help topic.")
endfork
"Last modified by Dax (#789) on Tue May  3 14:09:32 2005 MDT."
.