@verb #7171:"2who cwho" any any any rxdo #7407
@program #7171:"2who cwho" any any any
caller_perms() != player && raise(E_PERM)
set_task_perms(player)
if (argstr)
  if (!(ppl = #7070:match_players(@$string_utils:explode(argstr))))
    return player:tell("No players matched")
  endif
else
  ppl = connected_players()
endif
if (abs(player.output_linelength) <= 80)
  headers = {{30, 25, 25, 45}, {"Player", "#", "Idle", "Location"}}
elseif (!player:isa($guardian))
  headers = {{34, 8, 7, 8, 10, 45, 8}, {"Player", "#", "bit", "Idle", "Rank", "Location", "# Loc"}}
else
  headers = {{19, 8, 7, 8, 10, 35, 8, 25}, {"Player", "#", "bit", "Idle", "Rank", "Location", "# Loc", "Site"}}
endif
ldata = {}
data = {}
for x in (ppl)
  idle = x:connected() ? (is = x:idle_seconds()) < 30 ? " NO " | $cecil_utils:short_time(is) | "////"
  if (!#7070:is_malicious(x, "title"))
    xname = `tostr(x:title()) ! ANY => "! " + x.name'
  else
    xname = "@ " + x.name
  endif
  x:connected() && !x:connected(0) && (xname = "* " + xname)
  if (!$cecil_utils:is_malicious(x.location, "title") && !$cecil_utils:is_malicious(x.location, "msg_who_location"))
    locstr = `x.location:msg_who_location(x) ! ANY'
    locstr = typeof(locstr) == $STR ? locstr | `x.location:title(1) ! ANY => tostr("A broken room (", x.location, ")")'
  else
    locstr = "@ " + x.location.name
  endif
  bits = tostr(`x in player.friendlies ! E_PROPNF => 0' ? "f" | " ", x.wizard ? "W" | (x:isa($guardian) ? "G" | " "), `x.pueblo_version ! E_PROPNF' ? "P" | (`x.moozilla_version ! ANY' ? x.moozilla_version == $moozilla.latest_version ? "M" | "m" | " "))
  if (abs(player.output_linelength) <= 80)
    xdata = {xname, tostr(x), idle, locstr}
  elseif (!player:isa($guardian))
    xdata = {xname, tostr(x), bits, idle, x:rank(6), locstr, x.location}
  else
    conn = x:connected() ? $string_utils:connection_hostname(connection_name(x)) | "////"
    xdata = {xname, tostr(x), bits, idle, x:rank(6), locstr, x.location, conn}
  endif
  data = {@data, xdata}
  !$tcm && (locstr = $html_utils:detag(locstr))
  ldata = {@ldata, x.location == $www ? "~~~~~~~~~" | locstr}
  $cmd_utils:suspend_if_needed()
  "this:tell(toliteral(xdata));"
endfor
!$tcm && (data = $list_utils:sort(data, ldata))
player:tellColumns_suspended(3, @headers, @data)
"Last modified by Dax (#789) on Tue May  3 14:03:29 2005 MDT."
.