@verb #7165:"tellcolumns*_suspended" this none this rdo #60
@program #7165:"tellcolumns*_suspended" this none this
"Copied from Generic WWW connection (#81):tellcolumns by Hacker (#60)Aug  8 12:54:11 2002"
"Performs the same function as $player:TellColumns, but the output is tailored to the type of browser that the web user has."
if (typeof(args[1]) == $INT)
  if (args[1] in {1, 2, 3})
    justify = $string_utils:space(length(args[2]), "lcr"[args[1]])
    args = listdelete(args, 1)
  else
    raise(E_INVARG, "Justify parameter must be 1,2,3 or a string")
  endif
elseif (typeof(args[1]) == $STR)
  justify = args[1]
  args = listdelete(args, 1)
else
  justify = $string_utils:space(length(args[1]), "l")
endif
if (this.output_rendering_object != #282)
  "The broswer can't display tables, so enclose the columns in PRE tags."
  "Make the titles bold."
  title = 2
  for x in [1..length(args[title])]
    args[title][x] = tostr("<STRONG>", args[title][x], "</STRONG>")
  endfor
  return pass(justify, @args)
else
  "Assume that the browser can display tables."
  out = {}
  "We don't care about the ratios"
  args = listdelete(args, 1)
  for i in [1..length(args)]
    row = args[i]
    block = "<TR>"
    if (typeof(row) == $STR)
      block = tostr(block, "<TD COLSPAN=\"", length(justify), "\"><HR></TD>")
    else
      for j in [1..length(row)]
        col = row[j]
        td = i == 1 ? {"<TH>", "</TH>"} | {{"<TD>", "<TD ALIGN=\"center\">", "<TD ALIGN=\"right\">"}[justify[j] in {"l", "c", "r"}], "</TD>"}
        block = tostr(block, td[1], col, td[2])
      endfor
    endif
    out = {@out, block + "</TR>"}
    $command_utils:suspend_if_needed()
  endfor
  this:tell("<TABLE BORDER=1 cellspacing=1>", @out, "</TABLE>")
endif
"Last modified by Dax (#789) on Tue May  3 13:43:11 2005 MDT."
.