@verb #70:"object_page" this none this rxdo #60
@program #70:"object_page" this none this
{object} = args
tail = tostr($su.tab, $site, $su.tab, this.port)
if (!valid(object))
  data = {tostr("1'", object, "' doesn't exist!", $su.tab, tail)}
elseif (!$recycler:valid(object))
  data = {tostr("1'", object, "' has been recycled!", $su.tab, tail)}
else
  data = {tostr("0", object, " (", object.name, ")", $su.tab, "/", toint(object), ".description", tail)}
  if (object.r)
    for v in (verbs(object))
      data = {@data, tostr("0Verb:     ", object, ":", v, $su.tab, "/", toint(object), ":", v, tail)}
      $command_utils:suspend_if_needed()
    endfor
    for p in (properties(object))
      data = {@data, tostr("0Property: ", object, ".", p, $su.tab, "/", toint(object), ".", p, tail)}
      $command_utils:suspend_if_needed()
    endfor
    for f in (object:filelist())
      data = {@data, tostr("0File:     ", object, "!", f, $su.tab, "/", toint(object), "!", f, tail)}
      $command_utils:suspend_if_needed()
    endfor
  else
    data = {@data, tostr("iObject is unreadable.", $su.tab, $su.tab, "error.host", $su.tab, "1")}
  endif
  data = {@data, tostr("i", $su.tab, $su.tab, "error.host", $su.tab, "1")}
  if (valid(object.owner))
    data = {@data, this:object_link(object.owner, "Owner:   ")}
  endif
  if (valid(parent(object)))
    data = {@data, this:object_link(parent(object), "Parent:  ")}
  endif
  for child in (children(object))
    data = {@data, this:object_link(child, "Child:   ")}
    $command_utils:suspend_if_needed()
  endfor
  if (valid(object.location))
    data = {@data, this:object_link(object.location, "Location:")}
  endif
  for contains in (object.contents)
    data = {@data, this:object_link(contains, "Contains:")}
    $command_utils:suspend_if_needed()
  endfor
endif
return {@data, "."}
"Last modified by Dax (#789) on Tue May  3 14:09:30 2005 MDT."
.