@verb #6:"announce*_all_but" this none this rxdo #55
@program #6:"announce*_all_but" this none this
" :announce(text) - tells the text to everyone in the room, except 'player'."
" :announce_all(text) - tells the text to everyone in the room."
" :announce_all_but({exclude}, text) - tells the text to everyone in the room, except those in the list of 'exclude'."
if (verb == "announce")
  exclude = {player}
elseif (verb == "announce_all_but")
  exclude = args[1]
  exclude = {@exclude}
  args = listdelete(args, 1)
else
  exclude = {}
endif
listening = {}
for x in (this:contents(1))
  listening = {@listening, x}
  for y in (`x:contents(1) ! ANY => {}')
    if (`y.listen_in_location2 ! E_PROPNF => 0')
      listening = {@listening, y}
    endif
  endfor
endfor
for o in (listening)
  $command_utils:suspend_if_needed()
  if (!(o in exclude))
    try
      o:tell(@args)
    except (ANY)
      try
        r = verb_info(o, "notify")
        r[2] = $su:strip_chars(r[2], "x")
        set_verb_info(o, "notify", r)
        r = verb_info(o, "tell")
        r[2] = $su:strip_chars(r[2], "x")
        set_verb_info(o, "tell", r)
      except (ANY)
      endtry
      `o:tell("Your :notify or :tell verb appears to be broken.  I've taken the liberty of disabling it.") ! ANY => `$wiz_utils:guard_alert("Auto-notify-disabler in $room:announce: I've tried disabling " + tostr(o) + "'s tell and notify verbs, but I still can't :tell him without a traceback!") ! ANY''
    endtry
  endif
endfor
"Last modified by Dax (#789) on Thu May  5 16:41:46 2005 MDT."
.