@verb #6570:"tell_columns" this none this rxd #2633
@program #6570:"tell_columns" this none this
"EveFO:tell_columns(list<column widths>, list<column names>, list<lines>, [num<underline>], [num<footer>])"
"What this verb does is let you set up columns in a nice looking format. Each column can be set to a certain width, and they can also be underlined, and given a matching footer. (1 if true, 0 if not) (If a value is not given the foot is assumed to be 0 and the underline is assumed to be true). Each line is also a list containing the same number of items as there are columns. (This is not entirely necessary, but you better at least have 1 item in the list. If you are missing one, the tell_columns simply leaves that column blank.) Also, if you send an empty list for column widths it will assign them widths equal to the length of the columns' names. This also occurs if you don't have the same number of column widths as column names. Finally, column names will be shortened to the length of the column width if they are longer."
{cw, cn, lines, underline, foot} = {args[1], args[2], length(args) > 2 ? args[3] | {{""}}, length(args) > 3 ? args[4] | 1, length(args) > 4 ? args[5] | 0}
if (length(cn) != length(cw))
  cw = {}
  for c in (cn)
    cw = {@cw, length(c)}
  endfor
  cn = cn[1..length(cw)]
endif
header = footer = emptys = {}
for c in [1..length(cn)]
  header = {@header, (su = $string_utils):left(cn[c], cw[c])}
  footer = {@footer, su:space(cw[c], "-")}
  emptys = {@emptys, ""}
endfor
{underline ? lines = {footer, @lines} | 0, foot ? lines = {@lines, footer} | 0, lines = {header, @lines}}
for line in (lines)
  length(line) != length(cn) ? line = {@line, @emptys[length(line)..length(cn)]} | 0
  text = ""
  for i in [1..length(cn)]
    item = line[i]
    item ? 1 | (item = "")
    typeof(item) == $LIST ? item = toliteral(item) | 0
    text = text + su:left(tostr(item), cw[i]) + "  "
  endfor
  text = text[1..length(text) - 2]
  player:tell(text)
endfor
"Last modified by Dax (#789) on Tue May  3 13:55:56 2005 MDT."
.