@verb #6570:"@iprops" any none none rxd #61
@program #6570:"@iprops" any none none
"EveFO:@iprops #<obj>"
set_task_perms(caller_perms())
dobj = (p = player):my_match_object(argstr)
if (!argstr)
  return p:tell("Syntax:  @iprops #<obj>")
elseif (!$recycler:valid(dobj))
  return p:tell("No such object.")
elseif (!(props = properties(dobj)))
  return p:tell("There are no properties on ", $string_utils:nn(dobj), ".")
endif
iprops = {}
for prop in (props)
  try
    {owner, perms} = property_info(dobj, prop)
    value = tostr(toliteral(dobj.(prop)))
    length(value) > (ll = p:linelength()) - 36 ? value = value[1..ll - 39] + "..." | 0
  except e (ANY)
    {owner, perms, value} = {"#?", "????", e[1]}
  endtry
  typeof(value) == $LIST ? value = tostr(toliteral(value)) | 0
  iprops = {@iprops, {prop, tostr(owner), perms, value}}
endfor
p:tell($string_utils:center(tostr(" Information for properties on: ", $string_utils:nn(dobj), " "), ll, "-", "-"))
this:tell_columns({20, 5, 5, ll - 36}, {"property", "owner", "perms", "value"}, iprops, 1, 1)
"Last modified by Dax (#789) on Tue May  3 13:55:56 2005 MDT."
.