@verb #605:"user_connected" this none this rxdo #55
@program #605:"user_connected" this none this
{victim} = args
if (!caller_perms():controls(victim))
  raise(E_PERM)
endif
if (!victim.output_xdisplay)
  return
endif
pname = tostr("player_session_", toint(victim))
try
  add_property(this, pname, 0, {this.owner, ""})
except (E_INVARG)
  if (p = this.(pname))
    this:close_session(p[1])
  endif
  this.(pname) = 0
endtry
s = this:new_session(victim.output_xdisplay)
win = this:XCreateWindow(s, this:DefaultRootWindow(s), 100, 100, 512, 384, 1, 16, 0, 36, {"backing-store", "Always"}, {"event-mask", 2 ^ 15})
this.(pname) = {s, 0, 0, win}
cid = this:glXCreateContext(victim, 36, 0, 0)
this:XMapWindow(s, win)
c = this:glXMakeCurrent(victim, cid)
this:glViewport(victim, 0, 0, 512, 384)
this:glClear(victim, "color_buffer")
this:glXSwapBuffers(victim)
this:title_screen(victim)
"Last modified by manta (#7165) on Tue Apr 18 19:50:16 2000 EDT."
"This verb previously owned by manta (#7165), and chowned to $slacker upon dewizarding (Sat Aug 17 14:50:06 2002 MDT)."
"Last modified by Dax (#789) on Tue May  3 14:09:32 2005 MDT."
.