@verb #6052:"_kick" this none this rxdo #789
@program #6052:"_kick" this none this
"Begin generic security check (_kick)"
if (verb == "_kick" && !args[1]:isa(this))
  raise(E_INVARG, "Illegal object", args[1])
  return E_INVARG
endif
"End generic security check (_kick)"
"Locate all our non-canadian players."
"Although we have lots of US players, they are usually seen as .com"
domains = {"us"}
for dude in ($player:leaves())
  addy = tostr(dude.email_address)
  if (x = rindex(addy, "."))
    domain = addy[x + 1..$]
    if (length(domain) == 2)
      if (domain == "uk")
        domain = "gb"
      endif
      domains = setadd(domains, domain)
    endif
  endif
  $command_utils:suspend_if_needed()
endfor
"Canada shouldn't be here."
domains = setremove(domains, "ca")
codes = this:fileread("codes.txt")
countries = {}
for domain in (domains)
  for code in (codes)
    sep = index(code, ",")
    if (sep && domain == code[1..sep - 1])
      countries = {@countries, {domain, code[sep + 1..$]}}
      break
    endif
  endfor
endfor
this.countries = countries
"Last modified by Lao-Tzu (#8084) on Tue Dec 18 08:29:54 2001 MST."
.