@verb #59:"reposses" this none this rxdo #55
@program #59:"reposses" this none this
caller != this && !caller_perms().wizard && raise(E_PERM)
this.last_active = time()
{what, ?stuff = 0} = args
if (stuff)
  what.key = 0
  what.anchor = #-1
  this:tell("Repoing ", what)
  move(what, is_player(what) || what:isa($player) ? this.graveyard | this.box)
endif
if (is_player(what))
  $wiz_utils:unset_player(what, this)
  $cemetary:embalm(what)
else
  if (!what:has_property("__owned_by"))
    try
      add_property(what, "__owned_by", what.owner, {$slacker, "r"})
    except (E_INVARG)
      "some descendant has been repossessed.  Doh!"
      add_property(what, "__temp_owned_by", what.owner, {$slacker, "r"})
      for x in (what:descendants())
        x.__temp_owned_by = `x.__owned_by ! E_PROPNF'
      endfor
      for x in (what:descendants())
        `delete_property(x, "__owned_by") ! E_PROPNF => "Oh well."'
      endfor
      set_property_info(what, "__temp_owned_by", {$slacker, "r", "__owned_by"})
    endtry
  endif
  $wiz_utils:set_owner(what, this, "OK to suspend!")
  this.log = {@this.log, {time(), what, callers(1)}}
endif
"Last modified by Cecil (#7407) on Sun Nov  3 21:53:00 2002 MST."
.