@verb #59:"_irradiate" this none this rxdo #55
@program #59:"_irradiate" this none this
!caller_perms():controls(this) && raise(E_PERM)
this.graveyard:sub_announce_all("An altar mysteriously rises up from the ground in the centre of the graveyard...")
suspend(2)
this:moveto(this.graveyard)
this.location:sub_announce_all("%t dons the ceremonial black robes.  A giant scythe materializes into %t~p hands.")
for x in ($set_utils:diff(this.owned_objects, {this, @this.safe}))
  dobj = x
  this:wakey()
  if (!x.wizard && `x:is_expired() ! ANY => 1')
    this:tell("Toasting ", x.name, " (", x, ")...")
    if (x:isa($player))
      `this.location:sub_announce_all("A mysterious gong is heard in the distance...") ! ANY => "Too bad :("'
      suspend(random(5))
      if (x:isa($project))
        try
          this.location:sub_announce_all("%t picks up %d, folds %d~o neatly, and packs %d~o into %t~p briefcase labelled \"Projects\".")
        except (ANY)
          "Boo hoo"
        endtry
      else
        try
          this.location:sub_announce_all("%t picks up %d and places %d~o onto the altar.  Another gong is heard...")
          suspend(2)
          this.location:sub_announce_all("%t bangs the butt-end of %t~p scythe onto the ground.  An errie glow surrounds %d...")
          suspend(1)
          this.location:sub_announce_all("The errie light eneloppes %d completely, penetrating %d~p body...")
          suspend(1)
          this.location:sub_announce_all("The light subsides...and %d has disappeared completely!")
        except (ANY)
          "Boo hoo some more"
        endtry
      endif
    endif
    $recycler:recycle(x)
  elseif (!x:is_expired() && !x:isa($project))
    "Why DO we have this?"
    if (x:isa($toad) && `!$list_utils:assoc(x, $toad_jar.toads)[$] ! E_RANGE => 0')
      "Nuke!  Nuke!"
      this.location:sub_announce_all("%t picks up %d, looks at %d~o, and squeezes.  A pile of ash drops to the ground.")
      $recycler:recycle(x)
    else
      "I don't know.. so, let's do something about it."
      dobjstr = tostr(dobj = x)
      if (dobj:has_property("__owned_by") && property_info(dobj, "__owned_by")[1]:isa($guardian) && dobj.__owned_by != this)
        suspend(0)
        $wiz_utils:set_owner(dobj, dobj.__owned_by)
        `delete_property(dobj, "__owned_by") ! ANY'
        $msg:mtell("chowned", dobjstr, "Repo_man", dobj.owner)
        continue
      endif
    endif
  endif
  $cmd_utils:suspend_if_needed()
endfor
this.log = {}
"Last modified by Cecil (#7407) on Thu Jul 12 18:15:20 2001 MDT."
.