@verb #57:"funky_action(old)" this none this rxdo #55
@program #57:"funky_action(old)" this none this
if (caller != this)
  return
endif
player = this
{what, to, from, box} = args[1]
if (what.location != this)
  if (what.location != box)
    "Quack!"
    this:dequeue_delivery(what)
    return
  endif
  if (box:isa($po_box))
    box:open()
    dobjstr = tostr(dobj = what)
    box:take()
    box:close()
  elseif (box:isa($player))
    dobjstr = tostr(dobj = what)
    iobjstr = tostr(iobj = box)
    box:steal()
  else
    what:take()
  endif
  if (what.location != this)
    try
      what:moveto(this)
    except (ANY)
      move(what, this)
    endtry
  endif
endif
where = to.location
if (to:connected(0))
  while (this.location != where)
    $command_utils:suspend_if_needed()
    this:indirect_move(where)
    if (this.location != where)
      to:receive_page(this:msg_page_origin(), $msg:substitute("I have %1 (#%1~#) for you from %2 (#%2~#), but I can't seem to get into %3 (#%3~#). I'll try again later.", what, from, where))
      this:queue_delivery(what, to, from, this)
      return
    endif
    where = to.location
  endwhile
else
  "Quack."
  this:queue_delivery(what, to, from, this)
  return
endif
if (what.location != this)
  "QUACK?"
  return
endif
argstr = $msg:substitute("This was sent to you by %1:", from, what)
$command_utils:suspend_if_needed()
$object_utils:isa(this.location, $editor) || this.location:say()
iobjstr = tostr(iobj = to)
suspend(0)
what:give()
if (what.location == this)
  "Quack."
  this:queue_delivery(what, to, from, this)
endif
"Last modified by Dax (#789) on Thu Nov  8 15:28:55 2001 MST."
.