@verb #57:"funky_action" this none this rxdo #55
@program #57:"funky_action" this none this
if (caller != this)
  return
endif
player = this
try
  {what, to, from, box} = args[1]
except (E_ARGS, E_TYPE)
  return
  "Bah!  Bogus entry in .dispatch_queue."
endtry
this.last_commands = setadd(this.last_commands, tostr("Trying to deliver ", what, " to ", to, " from ", from, " (box: ", box, ")"))
if (!valid(what) || (!to:isa($room) && (!is_player(to) || !to:connected(0))))
  "Okie-Dokie Shuuure..."
  return
endif
if (what.location != box && what.location != this.mail_room)
  this.last_commands = setadd(this.last_commands, tostr("Object is not in it's designated box, nor my mail room. I'm confused. I'm taking a coffee break and trying someone else."))
  return
endif
what.anchor = #-1
if (box != this)
  where = box:isa($room) ? box | box.location
  this:indirect_move(where)
  suspend(1)
  `what.anchor = #-1 ! ANY'
  `what.key = 0 ! ANY'
  if (box:isa($po_box))
    this:get_from_box(what, box)
  elseif (box:isa($player))
    this:get_from_player(what, box)
  else
    dobjstr = tostr(dobj = what)
    `what:take() ! ANY'
  endif
endif
if (what.location != this)
  move(what, this)
  "I'll teach you..."
endif
if (to:isa($room))
  `this:indirect_move(where) ! E_VARNF => "Shutup!"'
  suspend(1)
  dobjstr = tostr(dobj = what)
  what:drop()
  move(what, this.location)
else
  if (to.location == what)
    "o/~ All for nothing...did you really want? o/~"
    return
  endif
  if (!to:isa($project) && !to:connected(0))
    this:requeue(what, to, from)
    return
    "How dare you disconnect, you twit!"
  endif
  where = to.location
  string = $msg:substitute("%1 I have %2 for you, sent by %3.  You are in %4, which I can't get into.  I'll try again later.", tostr(to), what, from, where)
  this:indirect_move(where)
  suspend(1)
  if (this.location != where)
    force_input(this, "page " + string)
    this:requeue(what, to, from)
    return
  endif
  string = $msg:substitute("This was sent to you by %1:", from)
  force_input(this, "say " + string)
  suspend(1)
  dobjstr = tostr(dobj = what)
  iobjstr = tostr(iobj = to)
  `what:give() ! ANY'
  move(what, to)
endif
if (what.location != to && what.location != to.location)
  move(what, to)
endif
"Last modified by Lao-Tzu (#8084) on Thu Jan 10 07:27:40 2002 MST."
"This verb previously owned by Raptor (#6319), and chowned to $slacker upon dewizarding (Sat Aug 17 14:48:42 2002 MDT)."
"Last modified by Dax (#789) on Sat Aug 17 14:48:42 2002 MDT."
.