@verb #555:"do_www_setup" this none this rxdo #789
@program #555:"do_www_setup" this none this
caller == this || raise(E_PERM)
pass(@args)
get = $www:parse_GET("q") || strsub(prepstr, "/", "")
if (get in {"unanswered", "answered", "ambiguous"})
  player:tell("<PRE>Searching for ", get, " questions...")
  log = this:fileread("log.txt")
  cache = {""}
  for line in ({@log, "*** End of log ***"})
    if (index(line, "    =>") == 1)
      cache = {@cache, line}
    else
      if (length(cache) == 2 ? cache[2] == "    => Huh?!?  ********************" ? get == "unanswered" | get == "answered" | get == "ambiguous")
        player:tell($html_utils:literal_text(get == "unanswered" ? cache[1] | cache))
      endif
      if (line && line[1] == "*")
        player:tell($html_utils:literal_text(line))
        cache = {}
      else
        cache = {line}
      endif
    endif
    $command_utils:suspend_if_needed()
  endfor
  player:tell("</PRE><HR>")
elseif (get == "reboot")
  this:reboot()
  player:tell("<HR>")
elseif (get == "check")
  this:check()
  player:tell("<HR>")
elseif (get == "rebootX")
  if ($code_utils:task_valid(this._reboot_task))
    kill_task(this._reboot_task)
    if (valid(this._reboot_thing) && parent(this._reboot_thing) == $thing && this._reboot_thing.name == "temporary Candid Candice object")
      $recycler:recycle(this._reboot_thing)
      this._reboot_thing = #-1
    endif
    this._reboot_buffer = this._reboot_db = {}
    player:tell("<B>The reboot has been terminated.</B><HR>")
  else
    "Huh?  Someone must have hit reload."
  endif
elseif (get == "checkX")
  if ($code_utils:task_valid(this._check_task))
    kill_task(this._check_task)
    player:tell("<B>The link checker has been terminated.</B><HR>")
  else
    "Huh?  Someone must have hit reload."
  endif
elseif (get == "delete")
  player:tell("<B>The logs have been deleted!</B><HR>")
  this:filewrite("log.txt", {"*** Start of log ***  " + ctime()})
endif
"Last modified by Dax (#789) on Wed Jan 16 21:51:48 2002 MST."
.