@verb #53:"www_recycle" this none this rxdo #55
@program #53:"www_recycle" this none this
caller == this || raise(E_PERM)
player:isa($webber) || raise(E_PERM)
set_task_perms(player.user)
if (player.referer)
  returnstr = player.referer
  returnobj = $www:previous_object()
else
  returnstr = tostr($www.url, "recycler")
  returnobj = this
endif
recycle = $www:parse_GET("recycle")
recycle || raise(E_INVARG, "No recycle argument, why are you here?")
recycle = toobj(recycle)
if (!valid(recycle) || !player.user:controls(recycle) || recycle == #0 || player.user == $no_one)
  $msg:mtell("www_error", "Permission denied!")
  player:tell("You cannot recycle ", $web:link(recycle, $su:nn(recycle)), ".")
  if (valid(returnobj))
    player:tell("Return to <A HREF=\"", returnstr, "\">", returnobj.name, "</A>.")
  endif
elseif ($www:parse_GET("returnstr") && $www:parse_GET("returnobj"))
  if ($www:previous_object() != this)
    "We have an unknown form refering a recycle to us with perms..."
    $msg:mtell("www_error", "Warning!  Previous page doesn't appear to be this one!")
    player:tell("For security reasons the recycle will not be executed.  Refering page: [", player.referer, "]")
    return
  endif
  this:recycle(recycle)
  returnstr = $www:parse_GET("returnstr")
  returnobj = toobj($www:parse_GET("returnobj"))
  if (!$recycler:valid(returnobj))
    returnstr = tostr($www.url, "recycler")
    returnobj = this
  endif
  player:tell("<H2>You have recycled ", recycle, ".</H2> Tell a Guardian if you need it retrieved.<BR>Return to <A HREF=\"", returnstr, "\">", returnobj.name, "</A>")
  player:tell("<P><CENTER><IMG SRC=\"", $www:fileURL(this, "nuke.jpg"), "\" HEIGHT=187 WIDTH=190 ALT=\"Nuked!\"></CENTER>")
else
  player:tell("<CENTER><IMG SRC=\"", $www:fileURL(this, "caution.gif"), "\" WIDTH=578 HEIGHT=16 ALT=\"[CAUTION!]\"></CENTER>")
  player:tell("<H2>Are you sure you want to permanently recycle ", $web:link(recycle), "?</H2>")
  player:tell("<UL><LI>Yes, <A HREF=\"/recycler", $www:integrate_cgi({{"recycle", tostr(toint(recycle))}, {"returnstr", returnstr}, {"returnobj", toint(returnobj)}}), "\">recycle ", $su:nn(recycle), "</A>!")
  player:tell("<P><LI>No, return to <A HREF=\"", returnstr, "\">", returnobj.name, "</A></UL>")
  player:tell("<CENTER><IMG SRC=\"", $www:fileURL(this, "caution.gif"), "\" WIDTH=578 HEIGHT=16 ALT=\"[CAUTION!]\"></CENTER>")
endif
"Last modified by Dax (#789) on Fri Sep 16 05:00:58 2005 MDT."
.