@verb #53:"image2text" this none this rxdo #58
@program #53:"image2text" this none this
what = args[1]
corrupt = args[2]
tod = args[3]
builtins = args[4]
flags = corrupt ? "(corrupt?) " | ""
flagnames = {"readable", "writable", "fertile", "(player)", "programmer", "wizard"}
for i in [6..11]
  if (builtins[i])
    flags = flags + flagnames[i - 5] + " "
  endif
endfor
text = {tostr(what:title(), " (Formerly ", builtins[1], ") [ ", flags, "]"), "Ancestors: " + $string_utils:from_list(builtins[3], " "), "Children: " + $string_utils:from_list(builtins[4], " "), tostr("Formerly owned by ", builtins[5], " and located at ", builtins[2], "."), "Died " + ctime(tod) + "."}
if (length(builtins) > 11)
  text = {@text, "Contents: " + $string_utils:from_list(builtins[12], " ")}
endif
if (length(args) > 6)
  for ci in (args[7])
    text = {@text, tostr("... called by ", ci[4], ":", ci[2], " (this == ", ci[1], ", player == ", ci[5], ", caller_perms() == ", ci[3], ")")}
  endfor
  for v in (args[6])
    text = {@text, tostr(v[3], " (", v[4], " ", v[5], " ", v[6], ") \"", v[2], "\" by ", v[1]), @v[7..length(v)], "."}
    $command_utils:suspend_if_needed()
  endfor
endif
for pset in (args[5])
  o = pset[1]
  for p in (pset[2])
    text = listappend(text, tostr(p[3], " (\"", p[2], "\" by ", p[1], ", on ", o, ") => ", toliteral(p[4])))
    $command_utils:suspend_if_needed()
  endfor
endfor
return text
"Last modified by Dax (#789) on Sat May 21 03:39:51 2005 MDT."
.