@verb #53:"_kick" this none this rxdo #55
@program #53:"_kick" this none this
"Begin generic security check (_kick)"
if (verb == "_kick" && !args[1]:isa(this))
  raise(E_INVARG, "Illegal object", args[1])
  return E_INVARG
endif
"End generic security check (_kick)"
this.net_task_id = 0
"Scan for any holes in the database and plug them."
"Start at -1 because we go through the loop once to see if there are any holes to fix at all"
count = -1
reset_max_object()
y = #-1
while (y != max_object())
  count = count + 1
  $hard_creating_tasks = setadd($hard_creating_tasks, task_id())
  x = create($root)
  $hard_creating_tasks = setadd($hard_creating_tasks, task_id())
  y = renumber(x)
  $recycler:recycle(y)
  $command_utils:suspend_if_needed()
  reset_max_object()
endwhile
$hard_creating_tasks = setadd($hard_creating_tasks, task_id())
recycle(y)
reset_max_object()
if (count)
  player:tell("Filled ", count, " holes.")
endif
$hard_creating_tasks = setremove($hard_creating_tasks, task_id())
"Garbage roundup!"
this:garbage_roundup()
if (!$code_utils:task_valid(this.refkiller_task))
  this:refkiller()
endif
"Last modified by Lao-Tzu (#8084) on Tue Dec 18 08:29:54 2001 MST."
"This verb previously owned by manta (#7165), and chowned to $slacker upon dewizarding (Sat Aug 17 14:50:05 2002 MDT)."
"Last modified by Cecil (#7407) on Tue Nov  5 18:20:17 2002 MST."
.