@verb #5335:"@monitor @unmonitor @monitoring" any none none rxo #60
@program #5335:"@monitor @unmonitor @monitoring" any none none
"Programmed by Daryl (#3887), hacked to itty-bitty bits by whiz.kid (#3135), and further ground and grinded by Raptor (#6319)."
"This verb has several diffrent forms to preform diffrent actions."
"@monitor and @unmonitor will do the obvious thing."
"@[un]monitor <player> will start monitoring or stop monitoring a player."
"@[un]monitor all will turn monitoring everyone on or off."
"@monitoring will list all players you are monitoring."
"Deactivated for the time being by Raptor"
m = (id = $list_utils:iassoc(player, this.monitoring)) ? this.monitoring[id][3] | {}
if (verb == "@monitoring")
  if (!m)
    return player:tell("You are currently monitoring everyone.")
  endif
  player:tell("You are monitoring:")
  if (#-1 in m)
    m = setremove(m, #-1)
    player:tell("everyone", m ? " but:" | ".")
  endif
  player:tell($string_utils:columnize($list_utils:map_verb(m, "title"), 3))
  return player:tell("You are ", this.monitoring[id][2] ? "" | "not ", "currently listening to connects and disconnects.")
endif
q = (verb in {"@unmonitor", "@monitor"}) - 1
if (!id)
  this.monitoring = {@this.monitoring, {player, 1, {#-1}}}
  id = length(this.monitoring)
endif
if (!argstr)
  this.monitoring[id][2] = q
  return player:tell("You are ", q ? "" | "not ", "currently listening to connects and disconnects.")
endif
victim = args[1] == "all" ? #-1 | $string_utils:match_player(args[1])
if (victim == $failed_match)
  return player:tell(args[1] + " does not exist.")
endif
if (victim == #-1 && q)
  this.monitoring = listdelete(this.monitoring, id)
  return player:tell("You are now monitoring everyone.")
elseif (victim == #-1 && !q)
  this.monitoring[id][3] = {}
  return player:tell("All monitors deleted.")
elseif (!!(#-1 in this.monitoring[id][3]) == q)
  this.monitoring[id][3] = setremove(this.monitoring[id][3], victim)
  player:tell("You are now monitoring ", victim:nn(), ".")
else
  this.monitoring[id][3] = setadd(this.monitoring[id][3], victim)
  player:tell("You are now not monitoring ", victim:nn(), ".")
endif
"Last modified by Raptor (#6319) on Fri Oct 30 16:24:44 1998 EST."
.