@verb #51:"lis*t ls*it view lst" any any any rxdo #60
@program #51:"lis*t ls*it view lst" any any any
"Copied from whiz.kid (#3135):view Jan  8 22:59:14 1996"
"Copied from Generic_Editor (#51):view by Hacker (#38) Jan  8 19:14:04 1996"
cp = valid(cp = caller_perms()) ? cp | player
nonum = 0
if (verb == "view")
  if (!dobjstr || dobj == this)
    l = {}
    for i in [1..length(this.active)]
      if (this.readable[i])
        l = {@l, this.active[i]}
      endif
    endfor
    if (l)
      player:tell("Players having readable texts in this editor:  ", $string_utils:name_and_number_list(l))
    else
      player:tell("No one has published anything in this editor.")
    endif
    return
  elseif ($command_utils:player_match_result(plyr = $string_utils:match_player(args[1]), args[1])[1])
    "...no such player"
    return
  elseif (!(who = this:loaded(plyr)) || (!this:readable(who) && !cp.wizard))
    player:tell(plyr.name, "(", plyr, ") has not published anything in this editor.")
    return
  elseif (prepstr == "in" && iobj == this)
    args = args[1..length(args) - 2]
  endif
  args = listdelete(args, 1)
  player:tell($string_utils:nn(plyr), " is working on ", this:working_on(who))
elseif (!(who = this:loaded(player)))
  player:tell(this:msg_nothing_loaded())
  return
endif
len = length(this.texts[who])
ins = this.inserting[who]
window = 8
if (len < 2 * window)
  default = {"1-$"}
elseif (ins <= window)
  default = {tostr("1-", 2 * window)}
else
  default = {tostr(window, "_-", window, "^"), tostr(2 * window, "$-$")}
endif
if (typeof(range = this:parse_range(who, default, @args)) != $LIST)
  player:tell(tostr(range))
elseif (range[3] && !(nonum = "nonum" == $string_utils:trim(range[3])))
  player:tell("Don't understand this:  ", range[3])
elseif (nonum)
  player:tell(this.texts[who][range[1]..range[2]])
else
  for line in [range[1]..range[2]]
    this:list_line(who, line)
    if ($command_utils:running_out_of_time())
      suspend(0)
      if (!(who = this:loaded(player)))
        player:tell("ack!  something bad happened during a suspend...")
        return
      endif
    endif
  endfor
  if (ins > len && len == range[2])
    player:tell("^^^^")
  endif
endif
"Last modified by Dax (#789) on Wed May  4 06:46:00 2005 MDT."
.