@verb #51:"left center centre right" any any any rdo #55
@program #51:"left center centre right" any any any
"Push the text in question to the left, right, or middle."
if (!(who = this:loaded(player)))
  player:tell(this:msg_nothing_loaded())
elseif (typeof(range = this:parse_range(who, {"_", "1"}, @args)) != $LIST)
  player:tell(range)
elseif (range[3])
  player:tell("Junk at end of cmd:  ", range[3])
else
  oldtext = this.texts[who]
  for x in [range[1]..range[2]]
    if (verb[1] == "l")
      while (this.texts[who][x][1] == " ")
        this.texts[who][x] = `this.texts[who][x][2..$] ! E_RANGE => ""'
      endwhile
    elseif (verb[1] == "r")
      "Assume that we want it aligned right to the player's linelength, or else $player:_get_output_linelength()."
      this.texts[who][x] = $su:right(this.texts[who][x], player:linelength())
    else
      len = player:linelength()
      len = len - length(this.texts[who][x])
      len = len / 2
      this.texts[who][x] = $su:space(len) + this.texts[who][x]
    endif
  endfor
  player:tell("Text aligned to the ", verb, ".")
  this.changes[who] = oldtext
  this.times[who] = time()
  this.inserting[who] = range[2] + 1
endif
"Last modified by Dax (#789) on Wed May  4 06:46:00 2005 MDT."
.