@verb #51:"ins*ert n*ext p*revious . isn" any none none rdo #60
@program #51:"ins*ert n*ext p*revious . isn" any none none
if (i = index(argstr, "\""))
  text = argstr[i + 1..length(argstr)]
  argstr = argstr[1..i - 1]
else
  text = 0
endif
spec = $string_utils:trim(argstr)
if (index("next", verb) == 1)
  verb = "next"
  spec = "+" + (spec || "1")
elseif (index("prev", verb) == 1)
  verb = "prev"
  spec = "-" + (spec || "1")
else
  spec = spec || "."
endif
if (!(who = this:loaded(player)))
  player:tell(this:msg_nothing_loaded())
elseif ($ERR == typeof(number = this:parse_insert(who, spec)))
  if (verb in {"next", "prev"})
    player:tell("Argument must be a number.")
  else
    player:tell("You must specify an integer or `$' for the last line.")
  endif
elseif (number > (max = length(this.texts[who]) + 1) || number < 1)
  player:tell("That would take you out of range (to line ", number, "?).")
else
  this.inserting[who] = number
  if (typeof(text) == $STR)
    text = player:input_get_raw(text)
    this:insert_line(who, text)
  else
    if (verb != "next")
      number > 1 ? this:list_line(who, number - 1) | player:tell("____")
    endif
    if (verb != "prev")
      number < max ? this:list_line(who, number) | player:tell("^^^^")
    endif
  endif
endif
"Last modified by Dax (#789) on Tue May  3 15:38:52 2005 MDT."
.