@verb #4843:"l*ooking r*egarder" any any any rxdo #7854
@program #4843:"l*ooking r*egarder" any any any
"Copied from Generic Room (#3):look by Slacker (#2) Jan 25 10:33:05 1997"
if (this.dark)
  return player:tell("It's too dark to see anything.")
endif
if (dobjstr == "" && !prepstr)
  this:look_self()
elseif (!(prepstr in {"in", "on", "dans", "sur"}))
  if (!dobjstr && prepstr == "at")
    dobjstr = iobjstr
    iobjstr = ""
  else
    dobjstr = dobjstr + (prepstr && (dobjstr && " ") + prepstr)
    dobjstr = dobjstr + (iobjstr && (dobjstr && " ") + iobjstr)
  endif
  dobj = this:match_object(dobjstr)
  if (!$command_utils:object_match_failed(dobj, dobjstr))
    dobj:look_self()
  endif
elseif (!iobjstr)
  $msg:mtell("no_iobj", verb, dobjstr, prepstr)
else
  iobj = this:match_object(iobjstr)
  if (!$command_utils:object_match_failed(iobj, iobjstr))
    if (dobjstr == "")
      iobj:look_self()
    elseif ((thing = iobj:match(dobjstr)) == $failed_match)
      $msg:mtell("not_contain", iobj, dobjstr)
    elseif (thing == $ambiguous_match)
      $msg:mtell("ambiguous", dobjstr)
    else
      thing:look_self()
    endif
  endif
endif
.